/*
 * Copyright (c) 2014 Balabit
 * Copyright (c) 2013 Tihamer Petrovics <tihameri@gmail.com>
 *
 * This program is free software; you can redistribute it and/or modify it
 * under the terms of the GNU General Public License version 2 as published
 * by the Free Software Foundation, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
 *
 * As an additional exemption you are allowed to compile & link against the
 * OpenSSL libraries as published by the OpenSSL project. See the file
 * COPYING for details.
 *
 */

%code requires {

#include "redis-parser.h"

}

%code {

#include "cfg-grammar-internal.h"
#include "plugin.h"
}

%define api.prefix {redis_}
%lex-param {CfgLexer *lexer}
%parse-param {CfgLexer *lexer}
%parse-param {LogDriver **instance}
%parse-param {gpointer arg}

/* INCLUDE_DECLS */

%token KW_REDIS
%token KW_COMMAND
%token KW_AUTH
%token KW_TIMEOUT

%%

start
        : LL_CONTEXT_DESTINATION KW_REDIS
          {
            last_driver = *instance = redis_dd_new(configuration);
          }
          '(' redis_options ')' { YYACCEPT; }
;

redis_options
        : redis_option redis_options
|
;

redis_option
        : KW_HOST '(' string ')'
          {
            redis_dd_set_host(last_driver, $3);
            free($3);
          }
        | KW_PORT '(' positive_integer ')'
          {
            redis_dd_set_port(last_driver, $3);
          }
        | KW_AUTH '(' string ')'
          {
            redis_dd_set_auth(last_driver, $3);
            free($3);
          }
        | KW_COMMAND '(' string template_content_list ')'
          {
            redis_dd_set_command_ref(last_driver, $3, $4);
            free($3);
          }
        | KW_TIMEOUT '(' nonnegative_integer ')'
          {
            redis_dd_set_timeout(last_driver, $3);
          }
        | threaded_dest_driver_general_option
        | threaded_dest_driver_workers_option
        | threaded_dest_driver_batch_option
        | { last_template_options = redis_dd_get_template_options(last_driver); } template_option
        ;

/* INCLUDE_RULES */

%%
