# file      : tests/variable/scope-specific/testscript
# license   : MIT; see accompanying LICENSE file

.include ../../common.testscript

: basic-line
:
$* <<EOI >>EOO
x = x
foo/ x = X
print $x
print $(foo/ x)
EOI
x
X
EOO

: basic-block
:
$* <<EOI >>EOO
x = x
foo/
{
  x = X
  [uint64] y = 00
  print $x
}
print $x
print $(foo/ y)
EOI
X
x
0
EOO

: unexpected-newline
:
$* <<EOI 2>>EOE != 0
foo/ y
EOI
<stdin>:1:7: error: unexpected <newline> after foo/ y
EOE

: expected-varname
:
$* <<EOI 2>>EOE != 0
foo/ [uint64] y = 0
EOI
<stdin>:1:1: error: expected variable name instead of foo/ [uint64] y
EOE

: unexpected-attribute
:
$* <<EOI 2>>EOE != 0
[uint64] foo/ y = 0
EOI
<stdin>:1:1: error: attributes before scope directory
EOE
