# file      : libbuild2/function+syntax.test.testscript
# license   : MIT; see accompanying LICENSE file

$* <'$dump()'           >:''                    : none
$* <'$dump(  )'         >:''                    : none-in-spaces
$* <'$dump("")'         >'{}'                   : one-empty
$* <'$dump(a)'          >'a'                    : one-single
$* <'$dump(a b c)'      >'a b c'                : one-list
$* <'$dump(d/t{x y z})' >'d/t{x} d/t{y} d/t{z}' : one-names

$* <'print a$dummy1([string] b)c'               >'abc' : concat
$* <'print $dummy2([uint64] 123, [uint64] 321)' >'444' : multi-arg

: quoting
: Verify we can inhibit function call with quoting
:
$* <<EOI >>EOO
foo = FOO
bar = BAR

print $foo"($bar)"
print "$foo"($bar)
print "$foo""($bar)"
EOI
FOOBAR
FOOBAR
FOOBAR
EOO
