* Parasitic-reduction self-test (.option minres / mincap)
*
* Rt (2->0) is 1 uohm, far below minres=1m, so node 2 is shorted to
* ground.  R1 then sees a pure 1k to ground, so i(V1) must be EXACTLY
* -1.000000000e-03.  With the short absent it would be -9.99999999e-4.
* Ctiny (2->0) is 1 aF, below mincap=1f, so it is removed.
*
* Expected console report:
*   Parasitic reduction:
*       resistors: shorted 1 of 2 (50.0%) < 0.001 ohm; 1 node(s) eliminated
*       capacitors: removed 1 of 1 (100.0%) < 1e-15 F
* Expected result:
*   i(v1) = -1.00000000000e-03
*
V1 1 0 DC 1
R1 1 2 1k
Rt 2 0 1u
Ctiny 2 0 1a
.option minres=1m mincap=1f
.control
op
set numdgt=12
print i(v1)
.endc
.end
