// See https://html.spec.whatwg.org/multipage/syntax.html#creating-and-inserting-nodes
%{
#include "replacement.h"
%}

%ignore-case
%struct-type
%omit-struct-type
%compare-lengths
%global-table
%readonly-tables
%null-strings
%includes
%define lookup-function-name gumbo_get_svg_attr_replacement
%define slot-name from
StringReplacement;

// "contentscripttype", "contentScriptType"
// "contentstyletype", "contentStyleType"
// "externalresourcesrequired", "externalResourcesRequired"
// "filterres", "filterRes"
%%
"attributename", "attributeName"
"attributetype", "attributeType"
"basefrequency", "baseFrequency"
"baseprofile", "baseProfile"
"calcmode", "calcMode"
"clippathunits", "clipPathUnits"
"diffuseconstant", "diffuseConstant"
"edgemode", "edgeMode"
"filterunits", "filterUnits"
"glyphref", "glyphRef"
"gradienttransform", "gradientTransform"
"gradientunits", "gradientUnits"
"kernelmatrix", "kernelMatrix"
"kernelunitlength", "kernelUnitLength"
"keypoints", "keyPoints"
"keysplines", "keySplines"
"keytimes", "keyTimes"
"lengthadjust", "lengthAdjust"
"limitingconeangle", "limitingConeAngle"
"markerheight", "markerHeight"
"markerunits", "markerUnits"
"markerwidth", "markerWidth"
"maskcontentunits", "maskContentUnits"
"maskunits", "maskUnits"
"numoctaves", "numOctaves"
"pathlength", "pathLength"
"patterncontentunits", "patternContentUnits"
"patterntransform", "patternTransform"
"patternunits", "patternUnits"
"pointsatx", "pointsAtX"
"pointsaty", "pointsAtY"
"pointsatz", "pointsAtZ"
"preservealpha", "preserveAlpha"
"preserveaspectratio", "preserveAspectRatio"
"primitiveunits", "primitiveUnits"
"refx", "refX"
"refy", "refY"
"repeatcount", "repeatCount"
"repeatdur", "repeatDur"
"requiredextensions", "requiredExtensions"
"requiredfeatures", "requiredFeatures"
"specularconstant", "specularConstant"
"specularexponent", "specularExponent"
"spreadmethod", "spreadMethod"
"startoffset", "startOffset"
"stddeviation", "stdDeviation"
"stitchtiles", "stitchTiles"
"surfacescale", "surfaceScale"
"systemlanguage", "systemLanguage"
"tablevalues", "tableValues"
"targetx", "targetX"
"targety", "targetY"
"textlength", "textLength"
"viewbox", "viewBox"
"viewtarget", "viewTarget"
"xchannelselector", "xChannelSelector"
"ychannelselector", "yChannelSelector"
"zoomandpan", "zoomAndPan"
