#compdef xargs

_arguments \
  '(-t)-p[prompt user for each command]' \
  '(-p)-t[verbose - echo each command]' \
  '-x[exit if max size exceeded]' \
  -{e-,E}':end-of-file string:' \
  '(-x -I)-i-:replacement string for lines:' \
  '(-x -i)-I:replacement string for lines:' \
  '(-n -L -x)-l-:number of input lines:' \
  '(-n -l)-L:number of input lines:' \
  '(-l -L)-n-:maximum number of arguments:' \
  '-s-:maximum command line length:' \
  '(-):command: _command_names -e' \
  '*::args: _normal'
