%%\bigskip\font\linus=linus \centerline{\linus l}\smallskip

%%The main `problem' is that this section is about graphic art rather than 
%%computer programming. Let's organize the file to emphasize the
%%essential features. First, we adjust for the screen:

screenstrokes;mode=localfont;mode_setup;
currenttransform:=identity shifted (10+xpart
  screen_topleft, 10-screen_rows + ypart screen_topleft);

beginchar("l",100pt#,100pt#,0); pickup pencircle scaled .8pt;

%eyebrows
draw (.49w,.86w)--(.555w,.89w); draw (.66w,.91w)--(.725w,.895w);
pickup pencircle xscaled .035w yscaled .07w rotated 10;

%%Minimalist art, in my opinion, is really more a scientific
%%investigation. It is interesting to see the maximum one can suggest
%%with the minimum of lines and colors. 

%eyes
drawdot (.49w,.63w); drawdot (.68w,.65w); pickup pencircle scaled .4pt;

%eye sockets
draw (.43w,.59w){dir 135}..(.42w,.63w){up}..{dir 65}(.46w,.72w);
draw (.7w,.76w){dir -45}..{down}(.75w,.68w)..(.745w,.645w);

%%Linus is the most interesting of Charles Schultz's characters. The
%%distinctive feature is the outline of his head. On the left we have
%%a `Cro-Magnon' skull:

draw (.3w,.51w)..{up}(.29w,.54w)..(.36w,.66w)..(.4w,.73w){up}
 ..(.36w,.87w){up}..(.46w,.97w){dir 20}..(.7w,1.1w){right} %Cro-Magnon
  ..(.83w,1.07w){dir -30}..{dir 265}(1.03w,.73w); %down to Charlie's ear

%%with an ear that, from a different angle, also functions as a nose.

draw (.29w,.54w){dir 170}..(.26w,.57w){up}..{right}(.36w,.66w);

%%Now let's draw some other stuff to give the image time to sink in. 
%%The left hand could definitely be improved. One might want to use
%%the `gnuchars' technique to put an announcement on the paper (or,
%%use kerns with \TeX--this is more flexible).

                                                
draw flex((.2w,.15h),(.14w,.3h),(.1w,.45h)) %front page
 & flex((.1w,.45w),(.4w,.42w),(.63w,.46w),(.68w,.45w))
  & flex((.68w,.45w),(.69w,.30w),(.7w,.18w));
draw flex ((.11w,.47w), (.3w,.46w),(.55w,.48w),(.71w,.47w))
 & flex ((.71w,.47w), (.72w,.31w),(.73w,.19w));
draw flex ((.13w,.49w),(.45w,.5w),(.75w,.49w))
 & flex ((.75w,.49w),(.76w, .38w), (.77w,.25w)); %back page
                                                 
draw (.24w,.16w)..(.4w,.12w){right}..(.5w,.13w);%paper creases
draw (.28w,.12w)..(.4w,.08w){dir -15}..(.53w,.06w);

%left hand
draw (1.01w,.01w)..(.95w,.15w)..(.92w,.17w){left}..(.85w,.2w){up}
 ..{dir 200}(.77w,.25w) ..{dir -45}(.79w,.17w)
 &(.79w,.17w){dir 135}..(.73w,.19w)..(.7w,.18w)
 ..(.72w,.1w)---(.77w,.11w)&(.77w,.11w)---(.72w,.1w)
 ..(.76w,.02w)---(.8w,.05w)&(.8w,.05w)---(.76w,.02w)
 ..(.81w,-.02w)---(.84w,.01w)&(.84w,.01w)---(.82w,-.02w)
 ..(.84w,-.03w)..(.88w,-.01)..{dir 80}(.89w,.02w)
 ---(1.01w,.01w)---cycle; 
%right fingers
draw (.2w,.15w)---(.18w,.21w)..(.15w,.22w){left}
 ..(.115w,.17w){down}..(.18w,.1w){right}..(.21w,.12w){up}..cycle;
draw (.12w,.14w)..(.11w,.07w)..(.16w,.04w){right}
 ..{dir 100}(.205w,.09w);
draw (.11w,.07w){dir 230}..(.15w,-.02w){right}..(.19w,.02w);

%%Now finish the `Charlie Brown' part of the face:
                                                
draw (1.03w,.73w){right}..(1.14w,.63w){down}..{dir 175}(1.03w,.56w);%ear
draw (1.03w,.56w){down}..{left}(.765w,.28w);
%nose
draw (.62w,.70w){dir 170}..(.55w,.7w)..(.54w,.65w){down}
 ..(.58w,.61w){dir 20}---(.61w,.62w);
%neck
draw (.8w,.282w)..(.805w,.255w);
%collar
fill (.85w,.2w){dir 40}..(.89w,.245w)---(.88w,.25w)---(.84w,.24w)
 ..(.85w,.22w)---cycle; 

%%Now Linus' trademark blanket, on the `Charlie' side.

draw (.85w,.20w){dir 40}..(1w,.3w)..(1.07w,.31w){right}
 ..(1.23w,.06w){dir -80};
draw (.9w,.2w)..(1w,.24w){right}..{dir -80}(1.14w,.01w);

%%And, finally, Linus' hair, which augments the basic figure. It
%%perhaps should have been drawn sooner; however,
%%from an interactive point of view, this gives the viewer time
%%to look at the figure. When \mf\ reads the {\tt end} statement, she
%%closes the window and exits.

draw (.46w,.97w){left}..(.31w,.9w)..(.25w,.78w);
draw (.7w,1.1w){dir 150}..(.46w,.97w)..{dir 285}(.46w,.83w);
draw (.7w,1.1w){left}..{dir 285}(.53w,.84w);
draw (.83w,1.07w){dir -50}..{dir 250}(.9w,.7w);
draw (.83w,1.07w){dir 135}..(.7w,1.1w)..{dir 280}(.57w,.8w);
draw (.7w,1.1w){right}..(.83w,1w)..(.9w,.75w);
draw (.535w,1.02w){dir 190}..(.37w,1.03w){left}..{down}(.15w,.77w);
draw (.92w,1w){dir -55}..{dir 250}(.95w,.7w);

%%What with all the other hard-coded coordinates, there seems little
%%point in using {\tt intersectiontimes {\rm or } intersectionpoint} here.

draw (.92w,1w){right}..(.96w,.99w)...{dir 250}(.95w,.68w);
draw (.92w,1w){dir 120}..{left}(.83w,1.07w)..(.69w,1w)
 ..{dir 250}(.59w,.87w);
draw (.92w,1w){dir 135}..(.69w,.9w){dir 240};
draw (.92w,1w){dir 185}..(.75w,.85w){dir 250};
endchar; end

%%Run {\tt mf linusa} to view the construction. You may need to slow
%%you computer down to get the effect I intended--I'm viewing this
%%myself on a 386sx/20 laptop with 4 megs ram (and with X, \mf, and
%%Emacs all running).
 
