%llogo.mf, v:0.1p2a - tdunbar@vtaix.cc.vt.edu
mode_setup; 
beginchar("L",1.4in#,1in#,.1in#); "The letter L (Linux logo)";
a:=h/100; pickup penrazor xscaled 2a; path p[];
p1:=(15a,10a)--(15a,40a); draw p1; 
draw p1 shifted (8a,0);  draw p1 shifted (25a,0);
p2:=(23a,40a)--(40a,10a); draw p2;
z1=(0,0);z2=(0,70a);z7=z2 shifted (5a,0);
z3=(-1a,80a);z6=z3 shifted (6.5a,0);
z4=(-10a,90a); z5=z4 shifted (17a,0);
z8=(5a,5a); z9=(55a,5a); z10=(70a,6a);z11=(85a,15a); z12=(85a,0); 
p3:=z1---z2{up}..z3..{left}z4&z4--z5&z5..z6..z7{down}---z8--cycle;
p4:=z8---z9..z10..{up}z11--z12--z1--cycle;
pickup pencircle scaled 1.2a; filldraw p3; filldraw p4;
%%\smallskip The L needs to be broken; otherwise there is a bad turning number
%%\smallskip
pickup pencircle scaled 3a; p4:=(50a,50a)--(50a,25a)..(51a,20a)..
 (65a,11a)..(79a,20a)..(80a,25a)--(80a,50a); draw p4;
pickup penrazor xscaled 4.5a rotated 20;
p5:=(90a,40a)--(110a,15a)--(90a,-10a); draw p5;
p6:=(130a,42a)--(110a,15a)--(130a,-8a);
draw p6 shifted (2a,-2a); 
endchar; 

%%\bigskip\font\llogo=llogo at 36pt\centerline{\llogo L}\bigskip
%a smaller version:
