# Maintainer:
# Contributor: Robert Brzozowski <robson75@linux.pl>
# Contributor: Charles Bos <charlesbos1 AT gmail>
# Contributor: Rob McCathie <archaur at rmcc dot com dot au
# Contributor: /dev/rs0 <rs0@secretco.de.com>
# Contributor: Iven Hsu <ivenvd AT gmail>
# Contributor: Nathan Hulse <nat.hulse@gmail.com>
# Adpeted to and included in Slint by Didier Spaier didieratslintdotfr
pkgname=compiz
pkgver=0.9.14.2
pkgrel=1slint
slackdesc="$pkgname (Composite manager for Aiglx and Xgl, with plugins and CCSM)"
arch=('x86_64')
url="https://launchpad.net/compiz"
license=('GPL' 'LGPL' 'MIT')
# These dependencies are for Arch according to the PKGBUID in the AUR.
# We do not need metacity, disabled in Slint.
depends=(
  'boost-libs'
  'fuse2'
  'glibmm'
  'glu'
  'libwnck3'
  'libxslt'
  'metacity'
  'protobuf'
  'python-cairo'
  'python-gobject'
  'xorg-server'
)
makedepends=(
  'boost'
  'cmake'
  'cython'
  'intltool'
)
optdepends=(
  'xorg-xprop: grab various window properties for use in window matching rules'
)
conflicts=(
  'ccsm'
  'compiz-bcop'
  'compiz-core'
  'compiz-fusion-plugins-experimental'
  'compiz-fusion-plugins-extra'
  'compiz-fusion-plugins-main'
  'compiz-gtk'
  'compizconfig-python'
  'libcompizconfig'
  'simple-ccsm'
)
provides=(
  "ccsm=$pkgver"
  "compiz-bcop=$pkgver"
  "compiz-core=$pkgver"
  "compiz-plugins-extra=$pkgver"
  "compiz-plugins-main=$pkgver"
  "compizconfig-python=$pkgver"
  "libcompizconfig=$pkgver"
)
source=(
  "https://launchpad.net/${pkgname}/${pkgver:0:6}/${pkgver}/+download/${pkgname}-${pkgver}.tar.xz"
  "focus-prevention-disable.patch"
  "gtk-extents.patch"
  "reverse-unity-config.patch"
  "screenshot-launch-fix.patch"
  "no-compile-gschemas.patch"
)
sha256sums=(
  'cfa061e93b032275ff9e7041f582a8f6d5ae271cf8a89e6bc74e3d3635999d3c'
  'f4897590b0f677ba34767a29822f8f922a750daf66e8adf47be89f7c2550cf4b'
  '16ddb6311ce42d958505e21ca28faae5deeddce02cb558d55e648380274ba4d9'
  '6ec9c04540ca1649c687d9ab2c8311caea7075831e2cffe719ec7958c9ebab7b'
  '89ee91a8ea6b1424ef76661ea9a2db43412366aacddc12d24a7adf5e04bfbc61'
  '4ab3277da201314b3f65e30128bc30704ddee584fdbbfc8d0d83c7e0de91fa9a'
)
doinst() {
# compile schemas
if [ -x /usr/bin/glib-compile-schemas ]; then
	/usr/bin/glib-compile-schemas usr/share/glib-2.0/schemas > /dev/null 2>&1
fi
}

docs=(AUTHORS COPYING COPYING.GPL COPYING.LGPL COPYING.MIT README)
options=(nosrcpack)
build() {
  cd $pkgname-$pkgver
  # Reverse Unity specific configuration patches
  patch -p1 -i "$SRC/reverse-unity-config.patch" --verbose || exit

  # Set focus prevention level to off which means that new windows will always get focus
  patch -p1 -i "$SRC/focus-prevention-disable.patch" --verbose || exit

  # Fix incorrect extents for GTK+ tooltips, csd etc
  patch -p1 -i "$SRC/gtk-extents.patch" --verbose || exit

  # Fix application launching for the screenshot plugin
  patch -p1 -i "$SRC/screenshot-launch-fix.patch" --verbose || exit

  # Don't try to compile gschemas during make install
  patch -p1 -i "$SRC/no-compile-gschemas.patch" --verbose || exit

sleep 5

  mkdir -p build
  cd build

  cmake .. \
    -DCMAKE_BUILD_TYPE="Release" \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DCMAKE_INSTALL_LIBDIR="/usr/lib64" \
    -DCOMPIZ_DISABLE_SCHEMAS_INSTALL=On \
    -DCOMPIZ_BUILD_WITH_RPATH=Off \
    -DCOMPIZ_PACKAGING_ENABLED=On \
    -DBUILD_GNOME=Off \
    -DBUILD_GTK=On \
    -DBUILD_METACITY=Off \
    -DCOMPIZ_BUILD_TESTING=Off \
    -DCOMPIZ_WERROR=Off

    make

  make DESTDIR="$PKG" install

  # findcompiz_install needs COMPIZ_DESTDIR and install needs DESTDIR
  # make findcompiz_install
  CMAKE_DIR=$(cmake --system-information | grep '^CMAKE_ROOT' | awk -F\" '{print $2}')
  install -Dm644 ../cmake/FindCompiz.cmake \
    -t "${PKG}${CMAKE_DIR}/Modules/"

  # Add the gsettings schema files
  if ls generated/glib-2.0/schemas/ | grep -qm1 .gschema.xml; then
    install -Dm644 generated/glib-2.0/schemas/*.gschema.xml \
      -t "$PKG/usr/share/glib-2.0/schemas/"
  fi
}