dnl withenable.ac: --with and --enable options.

# Check if the user wants to use Ghostscript, DPS or NeWS to
# display PostScript.
AC_ARG_WITH(ps,
[  --with-ps=PS            use PostScript; default gs (PS=no/yes/gs/dps/news)],
[case $withval in
  yes|gs) PS_DEF="$PS_DEF -DPS_GS";;
      no) PS_DEF=no;;
     dps) PS_DEF="$PS_DEF -DPS_DPS";;
    news) PS_DEF="$PS_DEF -DPS_NEWS";;
       *)] AC_MSG_WARN(Unknown --with-ps argument \`$withval'; using gs.);;
 esac)

AC_ARG_ENABLE(grey,
[  --disable-grey          disable greyscale anti-aliasing for shrunken bitmaps]
,
[if test "$enableval" = yes; then
  AC_DEFINE(GREY)
fi],
AC_DEFINE(GREY))

AC_ARG_ENABLE(buttons,
[  --disable-buttons       disable buttons on the side of the window],
[if test "$enableval" = yes; then
  AC_DEFINE(BUTTONS)
fi],
AC_DEFINE(BUTTONS))

AC_ARG_ENABLE(gf,
[  --enable-gf             enable gf format pixel files (in addition to pk)],
[if test "$enableval" != no; then
  AC_DEFINE(USE_GF)
  OPT_SRCS="$OPT_SRCS gf.c"
  OPT_OBJS="$OPT_OBJS gf.o"
fi])

AC_ARG_ENABLE(a4,
[  --enable-a4             set default paper size to A4 and default unit to cm],
[if test "$enableval" != no; then
  AC_DEFINE(A4)
fi])

