Conteúdo

# AGREGAR function

Esta função devolve o resultado agregado de um intervalo. A função AGREGAR permite-lhe ignorar linhas ocultas e valores de erro, bem como agregar outras funções, tais como aquelas que são listadas abaixo.

A função AGREGAR é aplicada a intervalos verticais de dados com o filtro automático ativado. Se o filtro automático não estiver ativado, o cálculo automático da função não funciona para novas linhas ocultas. Não é suposto esta função ser utilizada para intervalos horizontais mas também o pode ser, mas encontrará limitações. Mais concretamente, se a função for aplicada a intervalos horizontais, as colunas ocultas não serão reconhecidas, mas omite corretamente os erros e devolve o SUBTOTAL e as outras funções AGREGAR em apenas uma linha.

### Sintaxe

AGGREGATE(Function; Option; Number 1[; Number 2][; ... ;[Number 253]])

ou

AGGREGATE(Function; Option; Array[; k])

função (argumento obrigatório) é um índice de função ou a referência a uma célula com valor entre 1 e 19, de acordo com a seguinte tabela.

Índice de funções | Função aplicada
--- | ---
1 | MÉDIA
2 | CONTAR
3 | CONTAR.VAL
4 | MÁXIMO
5 | MÍNIMO
6 | PRODUTO
7 | DESVPAD.S
8 | DESVPAD.P
9 | SOMA
10 | VAR.S
11 | VAR.P
12 | MED
13 | MODA.SIMPLES
14 | MAIOR
15 | MENOR
16 | PERCENTIL.INC
17 | QUARTIL.INC
18 | PERCENTIL.EXC
19 | QUARTIL.EXC

For Integer arguments, non-integer values are truncated to Integer.

opções (argumento obrigatório). Um índice de opção ou a referência a uma célula com valor entre 0 e 7 que determina as partes do intervalo a ignorar.

Índice de opção | Opção aplicada
--- | ---
0 | Ignorar as funções SUBTOTAL e AGREGAR incorporadas
1 | Ignorar linhas ocultas e as funções SUBTOTAL e AGREGAR incorporadas
2 | Ignorar erros e as funções SUBTOTAL e AGREGAR incorporadas
3 | Ignorar linhas ocultas, erros e as funções SUBTOTAL e AGREGAR incorporadas
4 | Ignorar nada
5 | Ignorar linhas ocultas
6 | Ignorar erros
7 | Ignorar erros e linhas ocultas

For Integer arguments, non-integer values are truncated to Integer.

Number1 – required argument. The first numeric argument (if the range is set by a list of values inside the function) or a reference to a cell that contains it.

Number2, 3, ... – optional. A numeric argument or a reference to a cell (up to 253 arguments), for which you need the aggregate value.

Array – required argument. The array can be specified by the boundaries of the range, the name of the named range or the column label.

Para utilizar etiquetas de colunas, a opção "Localizar etiquetas de colunas e linhas automaticamente" tem de ser ativada.

k – required argument for the following functions: LARGE, SMALL, PERCENTILE.INC, QUARTILE.INC, PERCENTILE.EXC, QUARTILE.EXC. It is a numeric argument, which must correspond to the second argument of these functions.

### Exemplos

| A | B | C
1 | ColunaUm | ColunaDois | ColunaTrês
2 | 34 | 11 | 12
3 | 10 | 56 | 35
4 | #DIV/0! | 5 | 3
5 | 20 | 8 | 1
6 | 0 | 8 | 9
7 | #VALOR! | 20 | 21
8 | 5 | 7 | 8
9 | 14 | 0 | 5

=AGGREGATE(4;2;A2:A9)
Returns maximum value for the range A2:A9 = 34.

=AGREGAR(9;5;A5:C5)
Devolve 29, a soma do intervalo A5:C5 = 29, mesmo se algumas das colunas estiverem ocultas.

=AGREGAR(9;5;B2:B9)
Devolve 115, que é a soma da coluna B = 115. Se ocultar alguma linha, a função omite o seu valor. Por exemplo, se ocultar a linha 7 a função devolve 95.

Se necessitar de aplicar a função a um intervalo 3D, este exemplo mostra como o fazer.

=AGREGAR(13;3;Folha1.B2:B9:Folha3.B2:B9)
A função devolve 8, que é a moda dos valores da segunda coluna das folhas 1:3 (e que têm os mesmos dados) = 8.

Pode utilizar a referência a uma célula ou um intervalo para cada argumento da fórmula. O exemplo seguinte mostra como o fazer. Ademais, mostra que você pode utilizar etiquetas de coluna para especificar uma matriz.

=AGGREGATE(E3;E5;'ColumnOne')
If E3 = 13 and E5 = 5, the function returns mode of the first column = 10.

#### Technical information

Esta função está disponível desde o LibreOffice 4.4.

This function is NOT part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.AGGREGATE

Tópicos relacionados

AGGREGATE wiki page.

MÉDIA, CONTAR, CONTAR.VAL, MÁXIMO, MÍNIMO, PRODUTO, DESVPAD.S, DESVPAD.P, SOMA, VAR.S, VAR.P, MEDIANa, MODA.SIMPLES, MAIOR, MENOR, PERCENTIL.INC , QUARTIL.INC, PERCENTIL.EXC, QUARTIL.EXC

Localizar automaticamente etiquetas de colunas e linhas

Necessitamos da sua ajuda!