Vsebina

# AGGREGATE

Ta funkcija vrne skupni seštevek izračunov v obsegu. Uporabite lahko različne funkcije agregacije, ki so navedene spodaj. Ta funkcija omogoča izpuščanje skritih vrstic, napak ter rezultatov funkcij SUBTOTAL in drugih funkcij AGGREGATE v končnem izračunu.

Funkcija AGGREGATE se uporablja na navpičnih obsegih podatkov z aktiviranim samodejnim filtrom. Če samodejni filter ni aktiviran, samodejni ponoven izračun rezultata funkcije ne deluje na novo skritih vrsticah. Vodoravni obsegi niso podprti, vendar jo lahko z omejitvami uporabimo tudi zanje. Funkcija AGGREGATE na vodoravnem obsegu podatkov predvsem ne prepoznava skritih stolpcev, medtem ko pravilno izpušča napake in rezultate funkcij SUBTOTAL in drugih funkcij AGGREGATE, vdelanih v vrstico.

### Skladnja

AGGREGATE(funkcija; možnost; število 1 [; število 2][; ... ;[število 253]])

ali

AGGREGATE(funkcija; možnost; matrika[; k])

Funkcija – obvezen argument. Indeks funkcije ali sklic na celico z vrednostjo od 1 do 19 v skladu z naslednjo tabelo.

Indeks funkcije | Uporabljena funkcija
--- | ---
1 | AVERAGE
2 | COUNT
3 | COUNTA
4 | MAX
5 | MIN
6 | PRODUCT
7 | STDEV.S
8 | STDEV.P
9 | SUM
10 | VAR.S
11 | VAR.P
12 | MEDIAN
13 | MODE.SNGL
14 | LARGE
15 | SMALL
16 | PERCENTILE.INC
17 | QUARTILE.INC
18 | PERCENTILE.EXC
19 | QUARTILE.EXC

Če podani argument ni celo število, ko je to pričakovano, se okrajša na celoštevilsko vrednost.

Možnost – obvezen argument. Indeks možnosti ali sklic na celico z vrednostjo od 0 do 7 določa, kaj naj bo prezrto v obsegu za funkcijo.

Indeks možnosti | Uporabljena možnost
--- | ---
0 | Prezri le gnezdene funkcije SUBTOTAL in AGGREGATE
1 | Prezri le skrite vrstice ter gnezdene funkcije SUBTOTAL in AGGREGATE
2 | Prezri le napake ter gnezdene funkcije SUBTOTAL in AGGREGATE
3 | Prezri skrite vrstice, napake, gnezdene funkcije SUBTOTAL in AGGREGATE
4 | Ne prezri ničesar
5 | Prezri samo skrite vrstice
6 | Prezri samo napake
7 | Prezri le skrite vrstice in napake

Če podani argument ni celo število, ko je to pričakovano, se okrajša na celoštevilsko vrednost.

Število1 – obvezen argument. Prvi številski argument (če je obseg določen s seznamom vrednosti v funkciji) ali sklic na celico, ki ga vsebuje.

Število2,3 ... – neobvezno. Številski argument ali sklic na celico ali območje (do 253 argumentov), za katerega želite funkcijo združevanja.

Matrika – obvezen argument. Matriko lahko določite z mejami obsega, imenom imenovanega obsega ali z oznako stolpca.

Za uporabo oznak stolpcev morate omogočiti funkcijo »Samodejno poišči oznake stolpcev in vrstic«.

k – obvezni argument naslednjih funkcij: LARGE, SMALL, PERCENTILE.INC, QUARTILE.INC, PERCENTILE.EXC, QUARTILE.EXC. Gre za številski argument, ki mora ustrezati drugemu argumentu imenovanih funkcij.

### Primeri

| A | B | C
1 | PrviStolpec | DrugiStolpec | TretjiStolpec
2 | 34 | 11 | 12
3 | 10 | 56 | 35
4 | #DIV/0! | 5 | 3
5 | 20 | 8 | 1
6 | 0 | 8 | 9
7 | #VALUE! | 20 | 21
8 | 5 | 7 | 8
9 | 14 | 0 | 5

=AGGREGATE(4;2;A2:A9)
Vrne največjo vrednost v obsegu A2:A9, t.j. 34.

=AGGREGATE(9;5;A5:C5)
Vrne vsoto za obseg A5:C5, t.j. 29, čeprav so nekateri stolpci skriti.

=AGGREGATE(9;5;B2:B9)
Vrne vsoto stolpca B, t.j. 115. Če je katera od vrstic skrita, funkcija izpusti njeno vrednost, npr. če je 7. vrstica skrita, funkcija vrne 95.

Če želite uporabiti funkcijo z obsegom 3D, ta primer nakaže pot.

=AGGREGATE(13;3;DelovniList1.B2:B9:DelovniList3.B2:B9)
Funkcija vrne način vrednosti drugih stolpcev med delovnima listoma 1:3 (ki imajo enake podatke), t.j. 8.

Za vsak argument formule se lahko sklicujete na celico ali obseg. Naslednji primer prikazuje, kako deluje sklic. Poleg tega prikazuje, da lahko uporabite oznake stolpca za določitev matrike.

=AGGREGATE(E3;E5;'PrviStolpec')
Če je E3 enako 13 in E5 enako 5, funkcija vrne način prvega stolpca, t.j. 10.

#### Tehnični podatki

Ta funkcija je na voljo od LibreOffice 4.4.

Ta funkcija NI del standarda Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Imenski prostor je

COM.MICROSOFT.AGGREGATE

Podobne teme

Stran wiki o funkciji AGGREGATE (v angl.).

AVERAGE, COUNT, COUNTA, MAX, MIN, PRODUCT, STDEV.S, STDEV.P, SUM, VAR.S, VAR.P, MEDIAN, MODE.SNGL, LARGE, SMALL, PERCENTILE.INC , QUARTILE.INC, PERCENTILE.EXC, QUARTILE.EXC

Samodejno poišči oznake stolpcev in vrstic

Podprite nas!