# &kturtle;s &logo;-programmeringsreferens

## Kommandon

Du talar om för sköldpaddan eller &kturtle; att göra något med kommandon. Vissa kommandon behöver indata, vissa ger utdata. I det här avsnittet förklarar vi alla kommandon som kan användas i &kturtle;.

### Flytta sköldpaddan

Det finns flera kommandon för att flytta sköldpaddan över skärmen.

framåt

-     framåt X

  `framåt` flyttar sköldpaddan framåt X bildpunkter. När pennan är sänkt lämnar sköldpaddan ett spår. `framåt` kan förkortas `fr`.

bakåt

-     bakåt X

  `bakåt` flyttar sköldpaddan bakåt X bildpunkter. När pennan är sänkt lämnar sköldpaddan ett spår. `bakåt` kan förkortas `ba`.

svängvänster

-     svängvänster X

  `svängvänster` talar om för sköldpaddan att svänga X grader åt vänster. `svängvänster` kan förkortas till `sv`.

svänghöger

-     svänghöger X

  `svänghöger` talar om för sköldpaddan att svänga X grader åt höger. `svänghöger` kan förkortas till `sh`.

riktning

-     riktning X

  `riktning` ställer in sköldpaddans riktning till X grader från noll, och är på så sätt inte relativ till sköldpaddans tidigare riktning. `riktning` kan förkortas till `ri`.

mitten

-     mitten

  `mitten` flyttar sköldpaddan till dukens mitt.

gå

-     gå X,Y

  `gå` talar om för sköldpaddan att gå till en viss plats på duken. Den platsen är X bildpunkter från dukens vänsterkant och Y bildpunkter från dukens överkant. Observera att sköldpaddan inte ritar någon linje när kommandot `gå` används.

gåx

-     gåx X

  `gåx` gör att sköldpaddan flyttas X bildpunkter från dukens vänsterkant, medan höjden behålls.

gåy

-     gåy Y

  `gåy` gör att sköldpaddan flyttas Y bildpunkter från dukens överkant, medan avståndet från dukens vänsterkant behålls.

### Sköldpaddan har en penna

Sköldpaddan har en penna som ritar en linje medan sköldpaddan rör sig. Det finns några få kommandon att styra pennan. I det här avsnittet förklarar vi dessa kommandon.

höjpenna

-     höjpenna

  `höjpenna` lyfter pennan från duken. När pennan är höjd, ritas ingen linje när sköldpaddan rör sig. Se också `sänkpenna`. `höjpenna` kan förkortas till `hp`.

sänkpenna

-     sänkpenna

  `sänkpenna` sänker ner pennan på duken. När pennan är sänkt, ritas en linje när sköldpaddan rör sig. Se också `höjpenna`. `sänkpenna` kan förkortas till `sp`.

pennbredd

-     pennbredd X

  `pennbredd` ställer in pennans bredd (linjebredden) till X bildpunkter. `pennbredd` kan förkortas till `pb`.

pennfärg

-     pennfärg R,G,B

  `pennfärg` ställer in pennans färg. `pennfärg` behöver en RGB-kombination som indata. `pennfärg` kan förkortas till `pf`.

### Kommandon för att hantera duken

Det finns flera kommandon för att hantera duken.

dukstorlek

-     dukstorlek X,Y

  Med kommandot `dukstorlek` kan du ange dukens storlek. Det behöver X och Y som indata, där X är den nya dukbredden i bildpunkter och Y är den nya dukhöjden i bildpunkter. `dukstorlek` kan förkortas till `ds`.

dukfärg

-     dukfärg R,G,B

  `dukfärg` anger dukens färg. `dukfärg` behöver en RGB-kombination som indata. `dukfärg` kan förkortas till `df`.

rundpå

-     rundpå

  Med kommandot `rundpå` kan du runda duken. Se ordlistan om du vill veta vad runda betyder.

rundav

-     rundav

  Med kommandot `rundav` kan du göra motsatsen till att runda duken. Det betyder att sköldpaddan kan flyttas utanför duken och kan 'försvinna'. Se ordlistan om du vill veta vad runda betyder.

### Kommandon för att städa

Det finns två kommandon för att städa duken efter du har ställt till den.

rensa

-     rensa

  Med `rensa` suddar du allt som ritats på duken. Allt annat blir kvar: sköldpaddans position och vinkel, dukfärgen, sköldpaddans synlighet och dukstorleken.

återställ

-     återställ

  `återställ` städar mycket noggrannare än kommandot `rensa`. Efter kommandot `återställ` är allt som det var precis när du startat &kturtle;. Sköldpaddan är placerad i mitten av skärmen, dukfärgen är vit och sköldpaddan ritar en svart linje på duken.

### Sköldpaddan är en sprite

Många vet inte vad en sprite är, så här är en kort förklaring: En sprite är en liten bild som kan flyttas omkring på skärmen (för ytterligare information se ordförklaringen av sprite). Sköldpaddan är alltså en sprite!

Härnäst hittar du en fullständig översikt av alla kommandon som arbetar med en sprite.

(Kturtles nuvarande version stöder ännu inte användning av någon annan sprite än sköldpaddan. I framtida versioner kommer du att kunna ändra sköldpaddan till något som du själv skapat!)

visa

-     visa

  `visa` gör sköldpaddan synlig igen efter den har gömts.

göm

-     göm

  `göm` gömmer sköldpaddan. Det kan användas om sköldpaddan inte passar in i bilden.

### Kan sköldpaddan skriva text?

Svaret är ja. Sköldpaddan kan skriva. Han skriver nästan vad som helst som du talar om för honom att skriva.

skriv

-     skriv X

  Kommandot `skriv` används för att tala om för sköldpaddan att skriva någonting på duken. `skriv` behöver tal och strängar som indata. Du kan använda `skriv` för att skriva ut olika tal och strängar med symbolen '+'. Här är ett litet exempel:

      år = 2004
      upphovsman = "Cies"
      skriv "Kturtle skapades " + år + " av " + upphovsman

teckenstorlek

-     teckenstorlek X

  `teckenstorlek` anger storlek på teckensnittet som används av `skriv`. `teckenstorlek` behöver indata som ska vara ett tal. Storleken ställs in i bildpunkter.

### Ett kommando som rullar en tärning åt dig

Det finns ett kommando som rullar en tärning åt dig

slump

-     slump X,Y

  `slump` är ett kommando som kräver indata och ger utdata. Två tal krävs som indata, det första (X) anger minimal utdata och det andra (Y) anger maximal. Utdata är ett slumpmässigt valt tal som är större än eller lika med minimum och mindre än eller lika med maximum. Här är ett litet exempel:

            upprepa 500 [
              x = slump 1,20
              framåt x
              svängvänster 10 - x
            ]

  Med kommandot slump kan du lägga till en viss mängd kaos i programmet.

## Behållare

Behållare är bokstäver eller ord som kan användas av programmeraren för att lagra ett tal eller text. Behållare som innehåller ett tal kallas variabler, medan behållare som innehåller text kallas strängar.

Behållare som ännu inte har används är standardmässigt 0. Ett exempel:

    skriv N

Detta skriver ut 0.

### Variabler: talbehållare

Låt oss börja med ett exempel:

    x = 3
    skriv x

På första raden görs bokstaven `x` till en variabel (talbehållare). Som du ser sätts värdet på variabeln `x` till 3. På andra raden skrivs värdet ut.

Observera att om vi ville skriva ut ett x, skulle vi ha skrivit

    skriv "x"

Det var enkelt. Nu ett lite svårare exempel:

    A = 2004
    B = 25
    AB = A + B

    # nästa kommando skriver "2029"
    skriv AB
    bakåt 30
    # nästa kommando skriver "2004 plus 25"
    skriv A + " plus " + B
    bakåt 30
    # nästa kommando skriver "1979"
    skriv A - B

På de första två raderna sätts variablerna `A` och `B` till 2004 och 25. På den tredje raden sätts variabeln `AB` till `A + B`, vilket är 2029. Resten av exemplet består av tre kommandon `skriv` med `bakåt 30` mellan. Kommandot `bakåt 30` finns där för att vara säker på att all utskrift är på en ny rad. I exemplet ser du också att variabler kan användas i matematiska beräkningar.

### Strängar: textbehållare

Strängar är mycket lika variabler. Den största skillnaden är att strängar inte kan användas i matematiska beräkningar och frågor. Ett exempel på användning av strängar:

    x = "Hej "
    namn = indatafönster "Skriv in ditt namn..."
    skriv x + namn + ", hur står det till?

På första raden sätts strängen `x` till 'Hej '. På andra raden sätts strängen `namn` till utdata från kommandot `indatafönster`. På tredje raden skriver programmet ut en sammanslagning av de tre strängarna på duken.

Programmet ber dig skriva in ditt namn. Om du till exempel skriver in namnet Anna, skriver programmet ut Hej Anna, hur står det till?. Observera att plus (+) är den enda matematiska symbolen som du kan använda med strängar.

## Kan sköldpaddan räkna?

Ja, Kturtle räknar åt dig. Du kan addera (+), subtrahera (-), multiplicera (*) och dividera (/). Här är ett exempel där vi använder allihop:

    a = 20 - 5
    b = 15 * 2
    c = 30 / 30
    d = 1 + 1
    skriv "a: "+a+", b: "+b+", c: "+c+", d: "+d

Vet du vilka värden som a, b, c och d har?

Om du bara vill göra en enkel beräkning kan du skriva något som liknar detta:

    skriv 2004-12

Nu ett exempel med parenteser:

    skriv ( ( 20 - 5 ) * 2 / 30 ) + 1

Det som är mellan parenteser räknas ut först. I det här exemplet beräknas 20-5, och därefter multipliceras det med 2, divideras med 30 och därefter läggs 1 till (vilket ger 2).

## Ställa frågor, få svar ...

Kommandona `om` och `medan` styr körningen som diskuteras i nästa avsnitt. I det här avsnittet använder vi kommandot `om` för att förklara frågor.

Ett enkelt exempel på frågor:

    x = 6
    om x > 5 [
      skriv "Hej"
    ]

I det här exemplet är frågan `x > 5`. Om svaret på frågan är 'sant', utförs koden mellan hakparenteserna. Frågor är en viktig del av programmering, och används ofta tillsammans med kommandon som styr körningen, som `om`. Alla tal och variabler (talbehållare) kan jämföras med varandra med frågor.

Här är alla möjliga frågor:

## Typer av frågor

`a == b` | är lika med | svaret är sant om `a` är lika med `b`
`a != b` | inte lika med | svaret är sant om `a` inte är lika med `b`
`a > b` | större än | svaret är sant om `a` är större än `b`
`a < b` | mindre än | svaret är sant om `a` är mindre än `b`
`a >= b` | större än eller lika med | svaret är sant om `a` är större än eller lika med `b`
`a <= b` | mindre än eller lika med | svaret är sant om `a` är mindre än eller lika med `b`

Frågor kan också klistras ihop med 'sammanbindningsord'. På så sätt kan några få frågor bli en stor fråga.

    a = 1
    b = 5
    om a < 5 och b == 5 [
      skriv "Hej"
    ]

I det här exemplet används sammanbindningsordet `och` för att klistra ihop två frågor (`a < 5`, `b == 5`). Om en sida av `och` skulle ge svaret 'falskt', skulle svaret på hela frågan vara 'falskt', eftersom med sammanbindningsordet `och` måste båda sidor vara 'sanna' för att svaret ska vara 'sant'.

`och` är inte det enda sammanbindningsordet. Det finns ytterligare två. Alla finns i följande tabell:

## Sammanbindningsord i frågor

`och` | båda sidor måste vara sanna för att svaret ska vara sant
`eller` | om en av sidorna är sann är svaret sant
`inte` | bara om båda sidor är falska är svaret falskt

## Styra körning

Styrning av körningen gör det möjligt för dig att styra körningen, precis som namnet anger.

### Låta sköldpaddan vänta

Om du försökt programmera en del med &kturtle; kanske du märker att sköldpaddan kan vara mycket snabb när den ritar. Det här kommandot gör att sköldpaddan tar det lite lugnare.

vänta

-     vänta X

  `vänta` låter sköldpaddan vänta X sekunder.

            upprepa 36 [
              framåt 5
              svänghöger 10
              vänta 0.5
            ]

  Den här koden ritar en cirkel, men sköldpaddan väntar en halv sekund mellan varje steg. Det ger intrycket av en maklig sköldpadda.

### Kör "om"

om

-     om fråga [ ... ]

  Koden som ersätter '...' utförs bara `om` svaret på frågan är 'sant'. Läs gärna om frågor i avsnittet om frågor för mer information.

            x = 6
            om x > 5 [
              skriv "x är större än fem!"
            ]

  På den första raden sätts `x` till 6. På den andra raden ställs frågan `x > 5`. Eftersom svaret på frågan är 'sant', tillåter kommandot för styrning av körningen `om` att koden mellan hakparenteserna utförs.

### Kör "medan"

medan

-     medan fråga [ ... ]

  Kommandot för styrning av körningen `medan` liknar `om`. Skillnaden är att `medan` upprepar koden mellan hakparenteserna, ända till svaret på frågan blir 'falskt'.

            x = 1
            medan x < 5 [
              framåt 10
              vänta 1
              x = x + 1
            ]

  På den första raden sätts `x` till 1. På den andra raden ställs frågan `x < 5`. Eftersom svaret på frågan är 'sant' utför kommandot `medan` för styrning av körningen koden mellan hakparenteserna, ända till svaret på frågan blir 'falskt'. I det här fallet utförs koden mellan hakparenteserna 4 gånger, eftersom varje gång den femte raden utförs blir `x` ett större.

### Om inte, med andra ord "annars"

annars

-     om fråga [...] annars [ ... ]

  `annars` kan användas som tillägg till kommandot för styrning av körningen `om`. Koden mellan hakparenteserna efter `annars` utförs bara om svaret på frågan som ställs är 'falskt'.

            x = 4
            om x > 5 [
              skriv "x är större än fem!"
            ] annars [
              skriv "x är mindre än sex!"
            ]

  Frågan kontrollerar om `x` är större än 5. Eftersom `x` sätts till 4 på första raden är svaret på frågan 'falskt'. Det betyder att koden mellan hakparenteserna efter `annars` utförs.

### En "för" snurra

för

-     för startpunkt till slutpunkt [ ... ]

  Snurran `för` är en 'räknande snurra'. Den håller räkning åt dig.

            för x = 1 till 10 [
              skriv x * 7
              framåt 15
            ]

  Varje gång koden mellan hakparenteserna utförs är `x` ett större, till x når värdet 10. Koden mellan hakparenteserna skriver ut `x` multiplicerat med 7. Efter programmet har kört färdigt, ser du sjuans multiplikationstabell på duken.

## Skapa dina egna kommandon.

`lär` är ett mycket speciellt kommando, eftersom det används för att skapa dina egna kommandon. Kommandot som du skapar kan ha indata och returnera utdata. Låt oss ta en titt på hur ett nytt kommando skapas.

    lär cirkel (x) [
      upprepa 36 [
        framåt x
        svängvänster 10
      ]
    ]

Det nya kommandot kallas `cirkel`. `cirkel` har indata, ett tal som anger cirkelns storlek. `cirkel` returnerar ingen utdata. Kommandot `cirkel` kan nu användas som ett vanligt kommando. Se följande exempel:

    lär cirkel (x) [
      upprepa 36 [
        framåt x
        svängvänster 10
      ]
    ]

    gå 30,30
    cirkel (20)

    gå 40,40
    cirkel (50)

I nästa exempel skapas ett kommando som returnerar ett värde.

    lär multipliceraMedSigSjälv (n) [
      r = n * n
      returnera r
    ]
    tal = indatafönster "Ange ett tal och klicka på Ok"
    skriv tal + " multiplicerat med sig själv är: " + multipliceraMedSigSjälv (tal)

I det här exemplet skapas ett nytt kommando som heter `multipliceraMedSigSjälv`. Indata till kommandot multipliceras med sig själv och returneras med kommandot `returnera`. Kommandot `returnera` är sättet som används för att ge utdata från en funktion som du skapat själv.