Ada Reference Manual (Ada 2022) — Legal Information

# 5.5.1 User-Defined Iterator Types

#### Static Semantics

1/3
The following language-defined generic library package exists:
2/5
generic
type Cursor;
with function Has_Element (Position : Cursor) return Boolean;
package Ada.Iterator_Interfaces
with Pure, Nonblocking => False is
3/3
type Forward_Iterator is limited interface;
function First (Object : Forward_Iterator) return Cursor is abstract;
function Next (Object : Forward_Iterator; Position : Cursor)
return Cursor is abstract;
4/3
type Reversible_Iterator is limited interface and Forward_Iterator;
function Last (Object : Reversible_Iterator) return Cursor is abstract;
function Previous (Object : Reversible_Iterator; Position : Cursor)
return Cursor is abstract;
4.1/5
type Parallel_Iterator is limited interface and Forward_Iterator;
4.2/5
subtype Chunk_Index is Positive;
4.3/5
function Is_Split (Object : Parallel_Iterator)
return Boolean is abstract;
4.4/5
procedure Split_Into_Chunks (Object : in out Parallel_Iterator;
Max_Chunks : in Chunk_Index) is abstract
with Pre'Class => not Object.Is_Split or else raise Program_Error,
Post'Class => Object.Is_Split and then
Object.Chunk_Count <= Max_Chunks;
4.5/5
function Chunk_Count (Object : Parallel_Iterator)
return Chunk_Index is abstract
with Pre'Class => Object.Is_Split or else raise Program_Error;
4.6/5
function First (Object : Parallel_Iterator;
Chunk : Chunk_Index) return Cursor is abstract
with Pre'Class => (Object.Is_Split and then
Chunk <= Object.Chunk_Count)
or else raise Program_Error;
4.7/5
function Next (Object : Parallel_Iterator;
Position : Cursor;
Chunk : Chunk_Index) return Cursor is abstract
with Pre'Class => (Object.Is_Split and then
Chunk <= Object.Chunk_Count)
or else raise Program_Error;
4.8/5
type Parallel_Reversible_Iterator is limited interface
and Parallel_Iterator and Reversible_Iterator;
5/3
end Ada.Iterator_Interfaces;
6/5
An iterator type is a type descended from the Forward_Iterator interface from some instance of Ada.Iterator_Interfaces. A reversible iterator type is a type descended from the Reversible_Iterator interface from some instance of Ada.Iterator_Interfaces. A parallel iterator type is a type descended from the Parallel_Iterator interface from some instance of Ada.Iterator_Interfaces. A type descended from the Parallel_Reversible_Iterator interface from some instance of Ada.Iterator_Interfaces is both a parallel iterator type and a reversible iterator type. An iterator object is an object of an iterator type. A reversible iterator object is an object of a reversible iterator type. A parallel iterator object is an object of a parallel iterator type. The formal subtype Cursor from the associated instance of Ada.Iterator_Interfaces is the iteration cursor subtype for the iterator type.
7/3
The following type-related operational aspects may be specified for an indexable container type T (see 4.1.6):
8/5
Default_Iterator
This aspect is specified by a name that denotes exactly one function declared immediately within the same declaration list in which T, or the declaration completed by T, is declared, whose first parameter is of type T or T'Class or an access parameter whose designated type is type T or T'Class, whose other parameters, if any, have default expressions, and whose result type is an iterator type. This function is the default iterator function for T. Its result subtype is the default iterator subtype for T. The iteration cursor subtype for the default iterator subtype is the default cursor subtype for T. This aspect is inherited by descendants of type T (including T'Class).
9/5
Iterator_Element
This aspect is specified by a name that denotes a subtype. This is the default element subtype for T. This aspect is inherited by descendants of type T (including T'Class).
9.1/5
Iterator_View
This aspect is specified by a name that denotes a type T2 with the following properties:
9.2/5
T2 is declared in the same compilation unit as T;
9.3/5
T2 is an iterable container type;
9.4/5
T2 has a single discriminant which is an access discriminant designating T; and
9.5/5
The default iterator subtypes for T and T2 statically match.
9.6/5
This aspect is never inherited, even by T'Class.
10/5
This paragraph was deleted.
11/5
An iterable container type is an indexable container type with specified Default_Iterator and Iterator_Element aspects. A reversible iterable container type is an iterable container type with the default iterator type being a reversible iterator type. A parallel iterable container type is an iterable container type with the default iterator type being a parallel iterator type. An iterable container object is an object of an iterable container type. A reversible iterable container object is an object of a reversible iterable container type. A parallel iterable container object is an object of a parallel iterable container type.
11.1/4
The Default_Iterator and Iterator_Element aspects are nonoverridable (see 13.1.1).

#### Legality Rules

12/3
The Constant_Indexing aspect (if any) of an iterable container type T shall denote exactly one function with the following properties:
13/3
the result type of the function is covered by the default element type of T or is a reference type (see 4.1.5) with an access discriminant designating a type covered by the default element type of T;
14/3
the type of the second parameter of the function covers the default cursor type for T;
15/3
if there are more than two parameters, the additional parameters all have default expressions.
16/3
This function (if any) is the default constant indexing function for T.
17/3
The Variable_Indexing aspect (if any) of an iterable container type T shall denote exactly one function with the following properties:
18/3
the result type of the function is a reference type (see 4.1.5) with an access discriminant designating a type covered by the default element type of T;
19/3
the type of the second parameter of the function covers the default cursor type for T;
20/3
if there are more than two parameters, the additional parameters all have default expressions.
21/3
This function (if any) is the default variable indexing function for T.

#### Erroneous Execution

22/5
A call on the First or Next operation on a given Parallel_Iterator object with a given Chunk value, which does not propagate an exception, should return a Cursor value that either yields False when passed to Has_Element, or that identifies an element distinct from any Cursor value returned by a call on a First or Next operation on the same Parallel_Iterator object with a different Chunk value. If the First or Next operations with a Chunk parameter behave in any other manner, execution is erroneous.

Ada 2005 and 2012 Editions sponsored in part by Ada-Europe