CSV_XS(3)

NAME
Text::CSV_XS - comma-separated values manipulation routines

SYNOPSIS
 use Text::CSV_XS;

 my @rows;
 my $csv = Text::CSV_XS->new ({ binary => 1, auto_diag => 1 });
 open my $fh, "<:encoding(utf8)", "test.csv" or die "test.csv: $!";
 while (my $row = $csv->getline ($fh)) {
     $row->[2] =~ m/pattern/ or next; # 3rd field should match
     push @rows, $row;
     }
 close $fh;

 $csv->eol ("\r\n");
 open $fh, ">:encoding(utf8)", "new.csv" or die "new.csv: $!";
 $csv->print ($fh, $_) for @rows;
 close $fh or die "new.csv: $!";

DESCRIPTION
Text::CSV_XS provides facilities for the composition and decomposition of comma-separated values. An instance of the Text::CSV_XS class will combine fields into a CSV string and parse a CSV string into fields.

The module accepts either strings or files as input and support the use of user-specified characters for delimiters, separators, and escapes.

  Embedded newlines
Important Note: The default behavior is to accept only ASCII characters in the range from 0x20 (space) to 0x7E (tilde). This means that fields can not contain newlines. If your data contains newlines embedded in fields, or characters above 0x7e (tilde), or binary data, you must set "binary => 1" in the call to "new". To cover the widest range of parsing options, you will always want to set binary.

But you still have the problem that you have to pass a correct line to the "parse" method, which is more complicated from the usual point of usage:

 my $csv = Text::CSV_XS->new ({ binary => 1, eol => $/ });
 while (<>) {           #  WRONG!
     $csv->parse ($_);
     my @fields = $csv->fields ();

will break, as the while might read broken lines, as that does not care about the quoting. If you need to support embedded newlines, the way to go is to not pass "eol" in the parser (it accepts "\n", "\r", and "\r\n" by default) and then

 my $csv = Text::CSV_XS->new ({ binary => 1 });
 open my $io, "<", $file or die "$file: $!";
 while (my $row = $csv->getline ($io)) {
     my @fields = @$row;

The old(er) way of using global file handles is still supported

 while (my $row = $csv->getline (*ARGV)) {

  Unicode
Unicode is only tested to work with perl-5.8.2 and up.

On parsing (both for "getline" and "parse"), if the source is marked being UTF8, then all fields that are marked binary will also be marked UTF8.

For complete control over encoding, please use Text::CSV::Encoded:

 use Text::CSV::Encoded;
 my $csv = Text::CSV::Encoded->new ({
     encoding_in  => "iso-8859-1", # the encoding comes into   Perl
     encoding_out => "cp1252",     # the encoding comes out of Perl
     });

 $csv = Text::CSV::Encoded->new ({ encoding  => "utf8" });
 # combine () and print () accept *literally* utf8 encoded data
 # parse () and getline () return *literally* utf8 encoded data

 $csv = Text::CSV::Encoded->new ({ encoding  => undef }); # default
 # combine () and print () accept UTF8 marked data
 # parse () and getline () return UTF8 marked data

On combining ("print" and "combine"), if any of the combining fields was marked UTF8, the resulting string will be marked UTF8. Note however that all fields before the first field that was marked UTF8 and contained 8-bit characters that were not upgraded to UTF8, these will be bytes in the resulting string too, causing errors. If you pass data of different encoding, or you don't know if there is different encoding, force it to be upgraded before you pass them on:

 $csv->print ($fh, [ map { utf8::upgrade (my $x = $_); $x } @data ]);

SPECIFICATION
While no formal specification for CSV exists, RFC 4180 1) describes a common format and establishes "text/csv" as the MIME type registered with the IANA.

Many informal documents exist that describe the CSV format. How To: The Comma Separated Value (CSV) File Format 2) provides an overview of the CSV format in the most widely used applications and explains how it can best be used and supported.

 1) http://tools.ietf.org/html/rfc4180
 2) http://www.creativyst.com/Doc/Articles/CSV/CSV01.htm

The basic rules are as follows:

CSV is a delimited data format that has fields/columns separated by the comma character and records/rows separated by newlines. Fields that contain a special character (comma, newline, or double quote), must be enclosed in double quotes. However, if a line contains a single entry that is the empty string, it may be enclosed in double quotes. If a field's value contains a double quote character it is escaped by placing another double quote character next to it. The CSV file format does not require a specific character encoding, byte order, or line terminator format.

•   Each record is a single line ended by a line feed (ASCII/LF=0x0A) or a carriage return and line feed pair (ASCII/CRLF=0x0D 0x0A), however, line-breaks may be embedded.

•   Fields are separated by commas.

•   Allowable characters within a CSV field include 0x09 (tab) and the inclusive range of 0x20 (space) through 0x7E (tilde). In binary mode all characters are accepted, at least in quoted fields.

•   A field within CSV must be surrounded by double-quotes to contain a the separator character (comma).

Though this is the most clear and restrictive definition, Text::CSV_XS is way more liberal than this, and allows extension:

•   Line termination by a single carriage return is accepted by default

•   The separation-, escape-, and escape- characters can be any ASCII character in the range from 0x20 (space) to 0x7E (tilde). Characters outside this range may or may not work as expected. Multibyte characters, like U+060c (ARABIC COMMA), U+FF0C (FULLWIDTH COMMA), U+241B (SYMBOL FOR ESCAPE), U+2424 (SYMBOL FOR NEWLINE), U+FF02 (FULLWIDTH QUOTATION MARK), and U+201C (LEFT DOUBLE QUOTATION MARK) (to give some examples of what might look promising) are therefor not allowed.

    If you use perl-5.8.2 or higher, these three attributes are utf8-decoded, to increase the likelihood of success. This way U+00FE will be allowed as a quote character.

•   A field within CSV must be surrounded by double-quotes to contain an embedded double-quote, represented by a pair of consecutive double-quotes. In binary mode you may additionally use the sequence ""0" for representation of a NULL byte.

•   Several violations of the above specification may be allowed by passing options to the object creator.

FUNCTIONS

  version
(Class method) Returns the current module version.

  new
(Class method) Returns a new instance of Text::CSV_XS. The objects attributes are described by the (optional) hash ref "\%attr".

 my $csv = Text::CSV_XS->new ({ attributes ... });

The following attributes are available:

eol An end-of-line string to add to rows.

    When not passed in a parser instance, the default behavior is to accept "\n", "\r", and "\r\n", so it is probably safer to not specify "eol" at all. Passing "undef" or the empty string behave the same.

    Common values for "eol" are "\012" ("\n" or Line Feed), "\015\012" ("\r\n" or Carriage Return, Line Feed), and "\015" ("\r" or Carriage Return). The "eol" attribute cannot exceed 7 (ASCII) characters.

    If both $/ and "eol" equal "\015", parsing lines that end on only a Carriage Return without Line Feed, will be "parse"d correct.

sep_char
    The char used to separate fields, by default a comma. (","). Limited to a single-byte character, usually in the range from 0x20 (space) to 0x7e (tilde).

    The separation character can not be equal to the quote character. The separation character can not be equal to the escape character.

    See also "CAVEATS"

allow_whitespace
    When this option is set to true, whitespace (TAB's and SPACE's) surrounding the separation character is removed when parsing. If either TAB or SPACE is one of the three major characters "sep_char", "quote_char", or "escape_char" it will not be considered whitespace.

    Now lines like:

     1 , "foo" , bar , 3 , zapp

    are correctly parsed, even though it violates the CSV specs.

    Note that all whitespace is stripped from start and end of each field. That would make it more a feature than a way to enable parsing bad CSV lines, as

     1,   2.0,  3,   ape  , monkey

    will now be parsed as

     ("1", "2.0", "3", "ape", "monkey")

    even if the original line was perfectly sane CSV.

blank_is_undef
    Under normal circumstances, CSV data makes no distinction between quoted- and unquoted empty fields. These both end up in an empty string field once read, thus

     1,"",," ",2

    is read as

     ("1", "", "", " ", "2")

    When writing CSV files with "always_quote" set, the unquoted empty field is the result of an undefined value. To make it possible to also make this distinction when reading CSV data, the "blank_is_undef" option will cause unquoted empty fields to be set to undef, causing the above to be parsed as

     ("1", "", undef, " ", "2")

empty_is_undef
    Going one step further than "blank_is_undef", this attribute converts all empty fields to undef, so

     1,"",," ",2

    is read as

     (1, undef, undef, " ", 2)

    Note that this effects only fields that are really empty, not fields that are empty after stripping allowed whitespace. YMMV.

quote_char
    The character to quote fields containing blanks, by default the double quote character ("""). A value of undef suppresses quote chars (for simple cases only). Limited to a single-byte character, usually in the range from 0x20 (space) to 0x7e (tilde).

    The quote character can not be equal to the separation character.

allow_loose_quotes
    By default, parsing fields that have "quote_char" characters inside an unquoted field, like

     1,foo "bar" baz,42

    would result in a parse error. Though it is still bad practice to allow this format, we cannot help the fact some vendors make their applications spit out lines styled that way.

    If there is really bad CSV data, like

     1,"foo "bar" baz",42

    or

     1,""foo bar baz"",42

    there is a way to get that parsed, and leave the quotes inside the quoted field as-is. This can be achieved by setting "allow_loose_quotes" AND making sure that the "escape_char" is not equal to "quote_char".

escape_char
    The character to escape certain characters inside quoted fields. Limited to a single-byte character, usually in the range from 0x20 (space) to 0x7e (tilde).

    The "escape_char" defaults to being the literal double-quote mark (""") in other words, the same as the default "quote_char". This means that doubling the quote mark in a field escapes it:

     "foo","bar","Escape ""quote mark"" with two ""quote marks""","baz"

    If you change the default quote_char without changing the default escape_char, the escape_char will still be the quote mark. If instead you want to escape the quote_char by doubling it, you will need to change the escape_char to be the same as what you changed the quote_char to.

    The escape character can not be equal to the separation character.

allow_loose_escapes
    By default, parsing fields that have "escape_char" characters that escape characters that do not need to be escaped, like:

     my $csv = Text::CSV_XS->new ({ escape_char => "\\" });
     $csv->parse (qq{1,"my bar\'s",baz,42});

    would result in a parse error. Though it is still bad practice to allow this format, this option enables you to treat all escape character sequences equal.

allow_unquoted_escape
    There is a backward compatibility issue in that the escape character, when differing from the quotation character, cannot be on the first position of a field. e.g. with "quote_char" equal to the default """ and "escape_char" set to "\", this would be illegal:

     1,\0,2

    To overcome issues with backward compatibility, you can allow this by setting this attribute to 1.

binary
    If this attribute is TRUE, you may use binary characters in quoted fields, including line feeds, carriage returns and NULL bytes. (The latter must be escaped as ""0".) By default this feature is off.

    If a string is marked UTF8, binary will be turned on automatically when binary characters other than CR or NL are encountered. Note that a simple string like "\x{00a0}" might still be binary, but not marked UTF8, so setting "{ binary =" 1 }> is still a wise option.

decode_utf8
    This attributes defaults to TRUE.

    While parsing, fields that are valid UTF-8, are automatically set to be UTF-8, so that

      $csv->parse ("\xC4\xA8\n");

    results in

      PV("\304\250"\0) [UTF8 "\x{128}"]

    Sometimes it might not be a desired action. To prevent those upgrades, set this attribute to false, and the result will be

      PV("\304\250"\0)

types
    A set of column types; this attribute is immediately passed to the "types" method. You must not set this attribute otherwise, except for using the "types" method.

always_quote
    By default the generated fields are quoted only if they need to be. For example, if they contain the separator character. If you set this attribute to a TRUE value, then all defined fields will be quoted. ("undef" fields are not quoted, see "blank_is_undef")). This is typically easier to handle in external applications. (Poor creatures who are not using Text::CSV_XS. :-)

quote_space
    By default, a space in a field would trigger quotation. As no rule exists this to be forced in CSV, nor any for the opposite, the default is true for safety. You can exclude the space from this trigger by setting this attribute to 0.

quote_null
    By default, a NULL byte in a field would be escaped. This attribute enables you to treat the NULL byte as a simple binary character in binary mode (the "{ binary => 1 }" is set). The default is true. You can prevent NULL escapes by setting this attribute to 0.

quote_binary
    By default, all "unsafe" bytes inside a string cause the combined field to be quoted. By setting this attribute to 0, you can disable that trigger for bytes >= 0x7f.

keep_meta_info
    By default, the parsing of input lines is as simple and fast as possible. However, some parsing information - like quotation of the original field - is lost in that process. Set this flag to true to enable retrieving that information after parsing with the methods "meta_info", "is_quoted", and "is_binary" described below. Default is false.

verbatim
    This is a quite controversial attribute to set, but it makes hard things possible.

    The basic thought behind this is to tell the parser that the normally special characters newline (NL) and Carriage Return (CR) will not be special when this flag is set, and be dealt with as being ordinary binary characters. This will ease working with data with embedded newlines.

    When "verbatim" is used with "getline", "getline" auto-chomp's every line.

    Imagine a file format like

     M^^Hans^Janssen^Klas 2\n2A^Ja^11-06-2007#\r\n

    where, the line ending is a very specific "#\r\n", and the sep_char is a ^ (caret). None of the fields is quoted, but embedded binary data is likely to be present. With the specific line ending, that should not be too hard to detect.

    By default, Text::CSV_XS' parse function is instructed to only know about "\n" and "\r" to be legal line endings, and so has to deal with the embedded newline as a real end-of-line, so it can scan the next line if binary is true, and the newline is inside a quoted field. With this attribute, we tell parse () to parse the line as if "\n" is just nothing more than a binary character.

    For parse () this means that the parser has no idea about line ending anymore, and getline () chomps line endings on reading.

auto_diag
    Set to a true number between 1 and 9 will cause "error_diag" to be automatically be called in void context upon errors.

    In case of error "2012 - EOF", this call will be void.

    If set to a value greater than 1, it will die on errors instead of warn. If set to anything unsupported, it will be silently ignored.

    Future extensions to this feature will include more reliable auto-detection of the "autodie" module being enabled, which will raise the value of "auto_diag" with 1 on the moment the error is detected.

diag_verbose
    Set the verbosity of the "auto_diag" output. Currently only adds the current input line (if known) to the diagnostic output with an indication of the position of the error.

To sum it up,

 $csv = Text::CSV_XS->new ();

is equivalent to

 $csv = Text::CSV_XS->new ({
     quote_char            => '"',
     escape_char           => '"',
     sep_char              => ',',
     eol                   => $\,
     always_quote          => 0,
     quote_space           => 1,
     quote_null            => 1,
     quote_binary          => 1,
     binary                => 0,
     decode_utf8           => 1,
     keep_meta_info        => 0,
     allow_loose_quotes    => 0,
     allow_loose_escapes   => 0,
     allow_unquoted_escape => 0,
     allow_whitespace      => 0,
     blank_is_undef        => 0,
     empty_is_undef        => 0,
     verbatim              => 0,
     auto_diag             => 0,
     diag_verbose          => 0,
     });

For all of the above mentioned flags, an accessor method is available where you can inquire the current value, or change the value

 my $quote = $csv->quote_char;
 $csv->binary (1);

It is unwise to change these settings halfway through writing CSV data to a stream. If however, you want to create a new stream using the available CSV object, there is no harm in changing them.

If the "new" constructor call fails, it returns "undef", and makes the fail reason available through the "error_diag" method.

 $csv = Text::CSV_XS->new ({ ecs_char => 1 }) or
     die "".Text::CSV_XS->error_diag ();

"error_diag" will return a string like

 "INI - Unknown attribute 'ecs_char'"

  print
 $status = $csv->print ($io, $colref);

Similar to "combine" + "string" + "print", but way more efficient. It expects an array ref as input (not an array!) and the resulting string is not really created, but immediately written to the $io object, typically an IO handle or any other object that offers a "print" method.

For performance reasons the print method does not create a result string. In particular the "string", "status", "fields", and "error_input" methods are meaningless after executing this method.

If $colref is "undef" (explicit, not through a variable argument) and "bind_columns" was used to specify fields to be printed, it is possible to make performance improvements, as otherwise data would have to be copied as arguments to the method call:

 $csv->bind_columns (\($foo, $bar));
 $status = $csv->print ($fh, undef);

A short benchmark

 my @data = ("aa" .. "zz");
 $csv->bind_columns (\(@data));

 $csv->print ($io, [ @data ]);   # 10800 recs/sec
 $csv->print ($io,  \@data  );   # 57100 recs/sec
 $csv->print ($io,   undef  );   # 50500 recs/sec

  combine
 $status = $csv->combine (@columns);

This object function constructs a CSV string from the arguments, returning success or failure. Failure can result from lack of arguments or an argument containing an invalid character. Upon success, "string" can be called to retrieve the resultant CSV string. Upon failure, the value returned by "string" is undefined and "error_input" can be called to retrieve an invalid argument.

  string
 $line = $csv->string ();

This object function returns the input to "parse" or the resultant CSV string of "combine", whichever was called more recently.

  getline
 $colref = $csv->getline ($io);

This is the counterpart to "print", as "parse" is the counterpart to "combine": It reads a row from the IO object using "$io->getline" and parses this row into an array ref. This array ref is returned by the function or undef for failure.

When fields are bound with "bind_columns", the return value is a reference to an empty list.

The "string", "fields", and "status" methods are meaningless, again.

  getline_all
 $arrayref = $csv->getline_all ($io);
 $arrayref = $csv->getline_all ($io, $offset);
 $arrayref = $csv->getline_all ($io, $offset, $length);

This will return a reference to a list of getline ($io) results. In this call, "keep_meta_info" is disabled. If $offset is negative, as with "splice", only the last "abs ($offset)" records of $io are taken into consideration.

Given a CSV file with 10 lines:

 lines call
 ----- ---------------------------------------------------------
 0..9  $csv->getline_all ($io)         # all
 0..9  $csv->getline_all ($io,  0)     # all
 8..9  $csv->getline_all ($io,  8)     # start at 8
 -     $csv->getline_all ($io,  0,  0) # start at 0 first 0 rows
 0..4  $csv->getline_all ($io,  0,  5) # start at 0 first 5 rows
 4..5  $csv->getline_all ($io,  4,  2) # start at 4 first 2 rows
 8..9  $csv->getline_all ($io, -2)     # last 2 rows
 6..7  $csv->getline_all ($io, -4,  2) # first 2 of last  4 rows

  parse
 $status = $csv->parse ($line);

This object function decomposes a CSV string into fields, returning success or failure. Failure can result from a lack of argument or the given CSV string is improperly formatted. Upon success, "fields" can be called to retrieve the decomposed fields . Upon failure, the value returned by "fields" is undefined and "error_input" can be called to retrieve the invalid argument.

You may use the "types" method for setting column types. See "types"' description below.

  getline_hr
The "getline_hr" and "column_names" methods work together to allow you to have rows returned as hashrefs. You must call "column_names" first to declare your column names.

 $csv->column_names (qw( code name price description ));
 $hr = $csv->getline_hr ($io);
 print "Price for $hr->{name} is $hr->{price} EUR\n";

"getline_hr" will croak if called before "column_names".

Note that "getline_hr" creates a hashref for every row and will be much slower than the combined use of "bind_columns" and "getline" but still offering the same ease of use hashref inside the loop:

 my @cols = @{$csv->getline ($io)};
 $csv->column_names (@cols);
 while (my $row = $csv->getline_hr ($io)) {
     print $row->{price};
     }

Could easily be rewritten to the much faster:

 my @cols = @{$csv->getline ($io)};
 my $row = {};
 $csv->bind_columns (\@{$row}{@cols});
 while ($csv->getline ($io)) {
     print $row->{price};
     }

Your mileage may vary for the size of the data and the number of rows. With perl-5.14.2 the comparison for a 100_000 line file with 14 rows:

            Rate hashrefs getlines
 hashrefs 1.00/s       --     -76%
 getlines 4.15/s     313%       --

  getline_hr_all
 $arrayref = $csv->getline_hr_all ($io);
 $arrayref = $csv->getline_hr_all ($io, $offset);
 $arrayref = $csv->getline_hr_all ($io, $offset, $length);

This will return a reference to a list of getline_hr ($io) results. In this call, "keep_meta_info" is disabled.

  print_hr
 $csv->print_hr ($io, $ref);

Provides an easy way to print a $ref as fetched with getline_hr provided the column names are set with column_names.

It is just a wrapper method with basic parameter checks over

 $csv->print ($io, [ map { $ref->{$_} } $csv->column_names ]);

  column_names
Set the keys that will be used in the "getline_hr" calls. If no keys (column names) are passed, it'll return the current setting.

"column_names" accepts a list of scalars (the column names) or a single array_ref, so you can pass "getline"

 $csv->column_names ($csv->getline ($io));

"column_names" does no checking on duplicates at all, which might lead to unwanted results. Undefined entries will be replaced with the string "\cAUNDEF\cA", so

 $csv->column_names (undef, "", "name", "name");
 $hr = $csv->getline_hr ($io);

Will set "$hr->{"\cAUNDEF\cA"}" to the 1st field, "$hr->{""}" to the 2nd field, and "$hr->{name}" to the 4th field, discarding the 3rd field.

"column_names" croaks on invalid arguments.

  bind_columns
Takes a list of references to scalars to be printed with "print" or to store the fields fetched by "getline" in. When you don't pass enough references to store the fetched fields in, "getline" will fail. If you pass more than there are fields to return, the remaining references are left untouched.

 $csv->bind_columns (\$code, \$name, \$price, \$description);
 while ($csv->getline ($io)) {
     print "The price of a $name is \x{20ac} $price\n";
     }

To reset or clear all column binding, call "bind_columns" with a single argument "undef". This will also clear column names.

 $csv->bind_columns (undef);

If no arguments are passed at all, "bind_columns" will return the list current bindings or "undef" if no binds are active.

  eof
 $eof = $csv->eof ();

If "parse" or "getline" was used with an IO stream, this method will return true (1) if the last call hit end of file, otherwise it will return false (''). This is useful to see the difference between a failure and end of file.

  types
 $csv->types (\@tref);

This method is used to force that columns are of a given type. For example, if you have an integer column, two double columns and a string column, then you might do a

 $csv->types ([Text::CSV_XS::IV (),
               Text::CSV_XS::NV (),
               Text::CSV_XS::NV (),
               Text::CSV_XS::PV ()]);

Column types are used only for decoding columns, in other words by the "parse" and "getline" methods.

You can unset column types by doing a

 $csv->types (undef);

or fetch the current type settings with

 $types = $csv->types ();

IV  Set field type to integer.

NV  Set field type to numeric/float.

PV  Set field type to string.

  fields
 @columns = $csv->fields ();

This object function returns the input to "combine" or the resultant decomposed fields of a successful "parse", whichever was called more recently.

Note that the return value is undefined after using "getline", which does not fill the data structures returned by "parse".

  meta_info
 @flags = $csv->meta_info ();

This object function returns the flags of the input to "combine" or the flags of the resultant decomposed fields of "parse", whichever was called more recently.

For each field, a meta_info field will hold flags that tell something about the field returned by the "fields" method or passed to the "combine" method. The flags are bit-wise-or'd like:

" "0x0001
    The field was quoted.

" "0x0002
    The field was binary.

See the "is_***" methods below.

  is_quoted
 my $quoted = $csv->is_quoted ($column_idx);

Where $column_idx is the (zero-based) index of the column in the last result of "parse".

This returns a true value if the data in the indicated column was enclosed in "quote_char" quotes. This might be important for data where ",20070108," is to be treated as a numeric value, and where ","20070108"," is explicitly marked as character string data.

  is_binary
 my $binary = $csv->is_binary ($column_idx);

Where $column_idx is the (zero-based) index of the column in the last result of "parse".

This returns a true value if the data in the indicated column contained any byte in the range "[\x00-\x08,\x10-\x1F,\x7F-\xFF]".

  is_missing
 my $missing = $csv->is_missing ($column_idx);

Where $column_idx is the (zero-based) index of the column in the last result of "getline_hr".

 while (my $hr = $csv->getline_hr ($fh)) {
     $csv->is_missing (0) and next; # This was an empty line
     }

When using "getline_hr" for parsing, it is impossible to tell if the fields are "undef" because they where not filled in the CSV stream or because they were not read at all, as all the fields defined by "column_names" are set in the hash-ref. If you still need to know if all fields in each row are provided, you should enable "keep_meta_info" so you can check the flags.

  status
 $status = $csv->status ();

This object function returns success (or failure) of "combine" or "parse", whichever was called more recently.

  error_input
 $bad_argument = $csv->error_input ();

This object function returns the erroneous argument (if it exists) of "combine" or "parse", whichever was called more recently. If the last call was successful, "error_input" will return "undef".

  error_diag
 Text::CSV_XS->error_diag ();
 $csv->error_diag ();
 $error_code           = 0  + $csv->error_diag ();
 $error_str            = "" . $csv->error_diag ();
 ($cde, $str, $pos, $recno) = $csv->error_diag ();

If (and only if) an error occurred, this function returns the diagnostics of that error.

If called in void context, it will print the internal error code and the associated error message to STDERR.

If called in list context, it will return the error code and the error message in that order. If the last error was from parsing, the third value returned is a best guess at the location within the line that was being parsed. Its value is 1-based. The forth value represents the record count parsed by this csv object See examples/csv-check for how this can be used.

If called in scalar context, it will return the diagnostics in a single scalar, a-la $!. It will contain the error code in numeric context, and the diagnostics message in string context.

When called as a class method or a direct function call, the error diagnostics is that of the last "new" call.

  record_number
 $recno = $csv->record_number ();

Returns the records parsed by this csv instance. This value should be more accurate than $. when embedded newlines come in play. Records written by this instance are not counted.

  SetDiag
 $csv->SetDiag (0);

Use to reset the diagnostics if you are dealing with errors.

INTERNALS

Combine (...)
Parse (...)

The arguments to these two internal functions are deliberately not described or documented in order to enable the module author(s) to change it when they feel the need for it. Using them is highly discouraged as the API may change in future releases.

EXAMPLES

  Reading a CSV file line by line:
 my $csv = Text::CSV_XS->new ({ binary => 1, auto_diag => 1 });
 open my $fh, "<", "file.csv" or die "file.csv: $!";
 while (my $row = $csv->getline ($fh)) {
     # do something with @$row
     }
 close $fh or die "file.csv: $!";

Reading only a single column

 my $csv = Text::CSV_XS->new ({ binary => 1, auto_diag => 1 });
 open my $fh, "<", "file.csv" or die "file.csv: $!";
 # get only the 4th column
 my @column = map { $_->[3] } @{$csv->getline_all ($fh)};
 close $fh or die "file.csv: $!";

  Parsing CSV strings:
 my $csv = Text::CSV_XS->new ({ keep_meta_info => 1, binary => 1 });

 my $sample_input_string =
     qq{"I said, ""Hi!""",Yes,"",2.34,,"1.09","\x{20ac}",};
 if ($csv->parse ($sample_input_string)) {
     my @field = $csv->fields;
     foreach my $col (0 .. $#field) {
         my $quo = $csv->is_quoted ($col) ? $csv->{quote_char} : "";
         printf "%2d: %s%s%s\n", $col, $quo, $field[$col], $quo;
         }
     }
 else {
     print STDERR "parse () failed on argument: ",
         $csv->error_input, "\n";
     $csv->error_diag ();
     }

  Printing CSV data
The fast way: using "print"

An example for creating CSV files using the "print" method, like in dumping the content of a database ($dbh) table ($tbl) to CSV:

 my $csv = Text::CSV_XS->new ({ binary => 1, eol => $/ });
 open my $fh, ">", "$tbl.csv" or die "$tbl.csv: $!";
 my $sth = $dbh->prepare ("select * from $tbl");
 $sth->execute;
 $csv->print ($fh, $sth->{NAME_lc});
 while (my $row = $sth->fetch) {
     $csv->print ($fh, $row) or $csv->error_diag;
     }
 close $fh or die "$tbl.csv: $!";

The slow way: using "combine" and "string"

or using the slower "combine" and "string" methods:

 my $csv = Text::CSV_XS->new;

 open my $csv_fh, ">", "hello.csv" or die "hello.csv: $!";

 my @sample_input_fields = (
     'You said, "Hello!"',   5.67,
     '"Surely"',   '',   '3.14159');
 if ($csv->combine (@sample_input_fields)) {
     print $csv_fh $csv->string, "\n";
     }
 else {
     print "combine () failed on argument: ",
         $csv->error_input, "\n";
     }
 close $csv_fh or die "hello.csv: $!";

  The examples folder
For more extended examples, see the examples/ (1) sub-directory in the original distribution or the git repository (2).

 1. http://repo.or.cz/w/Text-CSV_XS.git?a=tree;f=examples
 2. http://repo.or.cz/w/Text-CSV_XS.git

The following files can be found there:

parser-xs.pl
    This can be used as a boilerplate to `fix' bad CSV and parse beyond errors.

     $ perl examples/parser-xs.pl bad.csv >good.csv

csv-check
    This is a command-line tool that uses parser-xs.pl techniques to check the CSV file and report on its content.

     $ csv-check files/utf8.csv
     Checked with examples/csv-check 1.5 using Text::CSV_XS 0.81
     OK: rows: 1, columns: 2
         sep = <,>, quo = <">, bin = <1>

csv2xls
    A script to convert CSV to Microsoft Excel. This requires Date::Calc and Spreadsheet::WriteExcel. The converter accepts various options and can produce UTF-8 Excel files.

csvdiff
    A script that provides colorized diff on sorted CSV files, assuming first line is header and first field is the key. Output options include colorized ANSI escape codes or HTML.

     $ csvdiff --html --output=diff.html file1.csv file2.csv

CAVEATS
"Text::CSV_XS" is not designed to detect the characters used to quote and separate fields. The parsing is done using predefined settings. In the examples sub-directory, you can find scripts that demonstrate how you can try to detect these characters yourself.

  Microsoft Excel
The import/export from Microsoft Excel is a risky task, according to the documentation in "Text::CSV::Separator". Microsoft uses the system's default list separator defined in the regional settings, which happens to be a semicolon for Dutch, German and Spanish (and probably some others as well). For the English locale, the default is a comma. In Windows however, the user is free to choose a predefined locale, and then change every individual setting in it, so checking the locale is no solution.

TODO

More Errors & Warnings
    New extensions ought to be clear and concise in reporting what error occurred where and why, and possibly also tell a remedy to the problem. error_diag is a (very) good start, but there is more work to be done here.

    Basic calls should croak or warn on illegal parameters. Errors should be documented.

setting meta info
    Future extensions might include extending the "meta_info", "is_quoted", and "is_binary" to accept setting these flags for fields, so you can specify which fields are quoted in the "combine"/"string" combination.

     $csv->meta_info (0, 1, 1, 3, 0, 0);
     $csv->is_quoted (3, 1);

Parse the whole file at once
    Implement new methods that enable parsing of a complete file at once, returning a list of hashes. Possible extension to this could be to enable a column selection on the call:

     my @AoH = $csv->parse_file ($filename, { cols => [ 1, 4..8, 12 ]});

    Returning something like

     [ { fields => [ 1, 2, "foo", 4.5, undef, "", 8 ],
         flags  => [ ... ],
         },
       { fields => [ ... ],
         .
         },
       ]

    Note that "getline_all" already returns all rows for an open stream, but this will not return flags.

  NOT TODO

combined methods
    Requests for adding means (methods) that combine "combine" and "string" in a single call will not be honored. Likewise for "parse" and "fields". Given the trouble with embedded newlines, using "getline" and "print" instead is the preferred way to go.

  Release plan
No guarantees, but this is what I had in mind some time ago:

next
     - This might very well be 1.00
     - DIAGNOSTICS setction in pod to *describe* the errors (see below)
     - croak / carp

next + 1
     - csv2csv - a script to regenerate a CSV file to follow standards

EBCDIC
The hard-coding of characters and character ranges makes this module unusable on EBCDIC systems.

Opening EBCDIC encoded files on ASCII+ systems is likely to succeed using Encode's cp37, cp1047, or posix-bc:

 open my $fh, "<:encoding(cp1047)", "ebcdic_file.csv" or die "...";

DIAGNOSTICS
Still under construction ...

If an error occurred, "$csv-"error_diag> can be used to get more information on the cause of the failure. Note that for speed reasons, the internal value is never cleared on success, so using the value returned by "error_diag" in normal cases - when no error occurred - may cause unexpected results.

If the constructor failed, the cause can be found using "error_diag" as a class method, like "Text::CSV_XS-"error_diag>.

"$csv-"error_diag> is automatically called upon error when the contractor was called with "auto_diag" set to 1 or 2, or when "autodie" is in effect. When set to 1, this will cause a "warn" with the error message, when set to 2, it will "die". "2012 - EOF" is excluded from "auto_diag" reports.

The errors as described below are available. I have tried to make the error itself explanatory enough, but more descriptions will be added. For most of these errors, the first three capitals describe the error category:

•   INI

    Initialization error or option conflict.

•   ECR

    Carriage-Return related parse error.

•   EOF

    End-Of-File related parse error.

•   EIQ

    Parse error inside quotation.

•   EIF

    Parse error inside field.

•   ECB

    Combine error.

•   EHR

    HashRef parse related error.

And below should be the complete list of error codes that can be returned:

•   1001 "INI - sep_char is equal to quote_char or escape_char"

    The separation character cannot be equal to either the quotation character or the escape character, as that will invalidate all parsing rules.

•   1002 "INI - allow_whitespace with escape_char or quote_char SP or TAB"

    Using "allow_whitespace" when either "escape_char" or "quote_char" is equal to SPACE or TAB is too ambiguous to allow.

•   1003 "INI - \r or \n in main attr not allowed"

    Using default "eol" characters in either "sep_char", "quote_char", or "escape_char" is not allowed.

•   2010 "ECR - QUO char inside quotes followed by CR not part of EOL"

    When "eol" has been set to something specific, other than the default, like "\r\t\n", and the "\r" is following the second (closing) "quote_char", where the characters following the "\r" do not make up the "eol" sequence, this is an error.

•   2011 "ECR - Characters after end of quoted field"

    Sequences like "1,foo,"bar"baz,2" are not allowed. "bar" is a quoted field, and after the closing quote, there should be either a new-line sequence or a separation character.

•   2012 "EOF - End of data in parsing input stream"

    Self-explaining. End-of-file while inside parsing a stream. Can happen only when reading from streams with "getline", as using "parse" is done on strings that are not required to have a trailing "eol".

•   2021 "EIQ - NL char inside quotes, binary off"

    Sequences like "1,"foo\nbar",2" are allowed only when the binary option has been selected with the constructor.

•   2022 "EIQ - CR char inside quotes, binary off"

    Sequences like "1,"foo\rbar",2" are allowed only when the binary option has been selected with the constructor.

•   2023 "EIQ - QUO character not allowed"

    Sequences like ""foo "bar" baz",quux" and "2023,",2008-04-05,"Foo, Bar",\n" will cause this error.

•   2024 "EIQ - EOF cannot be escaped, not even inside quotes"

    The escape character is not allowed as last character in an input stream.

•   2025 "EIQ - Loose unescaped escape"

    An escape character should escape only characters that need escaping. Allowing the escape for other characters is possible with the "allow_loose_escape" attribute.

•   2026 "EIQ - Binary character inside quoted field, binary off"

    Binary characters are not allowed by default. Exceptions are fields that contain valid UTF-8, that will automatically be upgraded is the content is valid UTF-8. Pass the "binary" attribute with a true value to accept binary characters.

•   2027 "EIQ - Quoted field not terminated"

    When parsing a field that started with a quotation character, the field is expected to be closed with a quotation character. When the parsed line is exhausted before the quote is found, that field is not terminated.

•   2030 "EIF - NL char inside unquoted verbatim, binary off"

•   2031 "EIF - CR char is first char of field, not part of EOL"

•   2032 "EIF - CR char inside unquoted, not part of EOL"

•   2034 "EIF - Loose unescaped quote"

•   2035 "EIF - Escaped EOF in unquoted field"

•   2036 "EIF - ESC error"

•   2037 "EIF - Binary character in unquoted field, binary off"

•   2110 "ECB - Binary character in Combine, binary off"

•   2200 "EIO - print to IO failed. See errno"

•   3001 "EHR - Unsupported syntax for column_names ()"

•   3002 "EHR - getline_hr () called before column_names ()"

•   3003 "EHR - bind_columns () and column_names () fields count mismatch"

•   3004 "EHR - bind_columns () only accepts refs to scalars"

•   3006 "EHR - bind_columns () did not pass enough refs for parsed fields"

•   3007 "EHR - bind_columns needs refs to writable scalars"

•   3008 "EHR - unexpected error in bound fields"

•   3009 "EHR - print_hr () called before column_names ()"

•   3010 "EHR - print_hr () called with invalid arguments"

SEE ALSO
perl, IO::File, IO::Handle, IO::Wrap, Text::CSV, Text::CSV_PP, Text::CSV::Encoded, Text::CSV::Separator, and Spreadsheet::Read.

AUTHORS and MAINTAINERS
Alan Citterman <alan@mfgrtl.com> wrote the original Perl module. Please don't send mail concerning Text::CSV_XS to Alan, as he's not involved in the C part that is now the main part of the module.

Jochen Wiedmann <joe@ispsoft.de> rewrote the encoding and decoding in C by implementing a simple finite-state machine and added the variable quote, escape and separator characters, the binary mode and the print and getline methods. See ChangeLog releases 0.10 through 0.23.

H.Merijn Brand <h.m.brand@xs4all.nl> cleaned up the code, added the field flags methods, wrote the major part of the test suite, completed the documentation, fixed some RT bugs and added all the allow flags. See ChangeLog releases 0.25 and on.

COPYRIGHT AND LICENSE
 Copyright (C) 2007-2013 H.Merijn Brand.  All rights reserved.
 Copyright (C) 1998-2001 Jochen Wiedmann. All rights reserved.
 Copyright (C) 1997      Alan Citterman.  All rights reserved.

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.