# Maintainer: Lieven Moors <lievenmoors at protonmail dot com>
# Contributor: Michał Szymański <smiszym at gmail dot com>
# Contributor: rtfreedman  (rob<d0t>til<d0t>freedman<aT>googlemail<d0t>com
# Contributor: Philipp Überbacher <murks at lavabit dot com>
# Adapted to Slint by Didier Spaier diideratslintdotfr
# patches from Debian
pkgname=traverso
pkgver=0.49.6
pkgrel=1
slackdesc="$pkgname (Digital Audio Workstation with an innovative User Interface)"
arch=('x86_64')
url="https://traverso-daw.org/"
license=('GPL')
depends=('qt5-base' 'fftw' 'wavpack' 'lame' 'libmad' 'lilv' 'hicolor-icon-theme' 'desktop-file-utils')
makedepends=('cmake')
source=("http://deb.debian.org/debian/pool/main/t/traverso/traverso_0.49.6.orig.tar.gz")
sha256sums=('f850b88cbb64529655514b7cfe01c56133e21929374b3e3b90813bc227eac789')
docs=("TODO" "HISTORY" "AUTHORS" "help.txt" "COPYRIGHT" "COPYING")
options=("nosrcpack")
build() {
  cd $pkgname-$pkgver
  while read patch; do
	patch -p1 --verbose < $startdir/patches/$patch || exit 1
  done < $startdir/patches/series
  mkdir build
  cd build
  cmake .. \
     -DCMAKE_INSTALL_PREFIX="/usr" \
     -DWANT_PULSEAUDIO=ON \
     -DWANT_PORTAUDIO=ON \
     -DWANT_MP3_ENCODE=ON
  make
  make DESTDIR="$PKG" install

  cd ../resources
  install -Dm644 traverso.desktop "$PKG"/usr/share/applications/traverso.desktop

  install -d "$PKG"/usr/share/icons/hicolor
  cp -a freedesktop/icons/* "$PKG"/usr/share/icons/hicolor

  install -Dm644 x-traverso.xml "$PKG"/usr/share/mime/packages/x-traverso.xml
  install -Dm644 help.text "$PKG"/usr/doc/traverso-$pkgver/help.txt  
}
