Control Structures

PostgreSQL 7.3.4 Documentation
Prev | Chapter 19. PL/pgSQL - SQL Procedural Language | Next

# 19.6. Control Structures

Control structures are probably the most useful (and important) part of PL/pgSQL. With PL/pgSQL's control structures, you can manipulate PostgreSQL data in a very flexible and powerful way.

## 19.6.1. Returning from a function

    RETURN expression;

RETURN with an expression is used to return from a PL/pgSQL function that does not return a set. The function terminates and the value of expression is returned to the caller.

To return a composite (row) value, you must write a record or row variable as the expression. When returning a scalar type, any expression can be used. The expression's result will be automatically cast into the function's return type as described for assignments. (If you have declared the function to return `void`, then the expression can be omitted, and will be ignored in any case.)

The return value of a function cannot be left undefined. If control reaches the end of the top-level block of the function without hitting a RETURN statement, a run-time error will occur.

When a PL/pgSQL function is declared to return SETOF sometype, the procedure to follow is slightly different. In that case, the individual items to return are specified in RETURN NEXT commands, and then a final RETURN command with no arguments is used to indicate that the function has finished executing. RETURN NEXT can be used with both scalar and composite data types; in the later case, an entire "table" of results will be returned. Functions that use RETURN NEXT should be called in the following fashion:

    SELECT * FROM some_func();

That is, the function is used as a table source in a FROM clause.

    RETURN NEXT expression;

RETURN NEXT does not actually return from the function; it simply saves away the value of the expression (or record or row variable, as appropriate for the data type being returned). Execution then continues with the next statement in the PL/pgSQL function. As successive RETURN NEXT commands are executed, the result set is built up. A final RETURN, which need have no argument, causes control to exit the function.

> Note: The current implementation of RETURN NEXT for PL/pgSQL stores the entire result set before returning from the function, as discussed above. That means that if a PL/pgSQL function produces a very large result set, performance may be poor: data will be written to disk to avoid memory exhaustion, but the function itself will not return until the entire result set has been generated. A future version of PL/pgSQL may allow users to allow users to define set-returning functions that do not have this limitation. Currently, the point at which data begins being written to disk is controlled by the SORT_MEM configuration variable. Administrators who have sufficient memory to store larger result sets in memory should consider increasing this parameter.

## 19.6.2. Conditionals

IF statements let you execute commands based on certain conditions. PL/pgSQL has four forms of IF:

- IF ... THEN

- IF ... THEN ... ELSE

- IF ... THEN ... ELSE IF and

- IF ... THEN ... ELSIF ... THEN ... ELSE

### 19.6.2.1. IF-THEN

    IF boolean-expression THEN
        statements
    END IF;

IF-THEN statements are the simplest form of IF. The statements between THEN and END IF will be executed if the condition is true. Otherwise, they are skipped.

    IF v_user_id <> 0 THEN
        UPDATE users SET email = v_email WHERE user_id = v_user_id;
    END IF;

### 19.6.2.2. IF-THEN-ELSE

    IF boolean-expression THEN
        statements
    ELSE
        statements
    END IF;

IF-THEN-ELSE statements add to IF-THEN by letting you specify an alternative set of statements that should be executed if the condition evaluates to FALSE.

    IF parentid IS NULL or parentid = ''''
    THEN
        return fullname;
    ELSE
        return hp_true_filename(parentid) || ''/'' || fullname;
    END IF;

    IF v_count > 0 THEN
        INSERT INTO users_count(count) VALUES(v_count);
        return ''t'';
    ELSE
        return ''f'';
    END IF;

### 19.6.2.3. IF-THEN-ELSE IF

IF statements can be nested, as in the following example:

    IF demo_row.sex = ''m'' THEN
      pretty_sex := ''man'';
    ELSE
      IF demo_row.sex = ''f'' THEN
        pretty_sex := ''woman'';
      END IF;
    END IF;

When you use this form, you are actually nesting an IF statement inside the ELSE part of an outer IF statement. Thus you need one END IF statement for each nested IF and one for the parent IF-ELSE. This is workable but grows tedious when there are many alternatives to be checked.

### 19.6.2.4. IF-THEN-ELSIF-ELSE

    IF boolean-expression THEN
        statements
    [ ELSIF boolean-expression THEN
        statements
    [ ELSIF boolean-expression THEN
        statements
        ...]]
    [ ELSE
        statements ]
    END IF;

IF-THEN-ELSIF-ELSE provides a more convenient method of checking many alternatives in one statement. Formally it is equivalent to nested IF-THEN-ELSE-IF-THEN commands, but only one END IF is needed.

Here is an example:

    IF number = 0 THEN
        result := ''zero'';
    ELSIF number > 0 THEN
        result := ''positive'';
    ELSIF number < 0 THEN
        result := ''negative'';
    ELSE
        -- hmm, the only other possibility is that number IS NULL
        result := ''NULL'';
    END IF;

The final ELSE section is optional.

## 19.6.3. Simple Loops

With the LOOP, EXIT, WHILE and FOR statements, you can arrange for your PL/pgSQL function to repeat a series of commands.

### 19.6.3.1. LOOP

    [<<label>>]
    LOOP
        statements
    END LOOP;

LOOP defines an unconditional loop that is repeated indefinitely until terminated by an EXIT or RETURN statement. The optional label can be used by EXIT statements in nested loops to specify which level of nesting should be terminated.

### 19.6.3.2. EXIT

    EXIT [ label ] [ WHEN expression ];

If no label is given, the innermost loop is terminated and the statement following END LOOP is executed next. If label is given, it must be the label of the current or some outer level of nested loop or block. Then the named loop or block is terminated and control continues with the statement after the loop's/block's corresponding END.

If WHEN is present, loop exit occurs only if the specified condition is true, otherwise control passes to the statement after EXIT.

Examples:

    LOOP
        -- some computations
        IF count > 0 THEN
            EXIT;  -- exit loop
        END IF;
    END LOOP;

    LOOP
        -- some computations
        EXIT WHEN count > 0;
    END LOOP;

    BEGIN
        -- some computations
        IF stocks > 100000 THEN
            EXIT;  -- illegal. Can't use EXIT outside of a LOOP
        END IF;
    END;

### 19.6.3.3. WHILE

    [<<label>>]
    WHILE expression LOOP
        statements
    END LOOP;

The WHILE statement repeats a sequence of statements so long as the condition expression evaluates to true. The condition is checked just before each entry to the loop body.

For example:

    WHILE amount_owed > 0 AND gift_certificate_balance > 0 LOOP
        -- some computations here
    END LOOP;

    WHILE NOT boolean_expression LOOP
        -- some computations here
    END LOOP;

### 19.6.3.4. FOR (integer for-loop)

    [<<label>>]
    FOR name IN [ REVERSE ] expression .. expression LOOP
        statements
    END LOOP;

This form of FOR creates a loop that iterates over a range of integer values. The variable name is automatically defined as type integer and exists only inside the loop. The two expressions giving the lower and upper bound of the range are evaluated once when entering the loop. The iteration step is normally 1, but is -1 when REVERSE is specified.

Some examples of integer FOR loops:

    FOR i IN 1..10 LOOP
      -- some expressions here

        RAISE NOTICE ''i is %'',i;
    END LOOP;

    FOR i IN REVERSE 10..1 LOOP
        -- some expressions here
    END LOOP;

## 19.6.4. Looping Through Query Results

Using a different type of FOR loop, you can iterate through the results of a query and manipulate that data accordingly. The syntax is:

    [<<label>>]
    FOR record | row IN select_query LOOP
        statements
    END LOOP;

The record or row variable is successively assigned all the rows resulting from the SELECT query and the loop body is executed for each row. Here is an example:

    CREATE FUNCTION cs_refresh_mviews () RETURNS INTEGER AS '
    DECLARE
         mviews RECORD;
    BEGIN
         PERFORM cs_log(''Refreshing materialized views...'');

         FOR mviews IN SELECT * FROM cs_materialized_views ORDER BY sort_key LOOP

             -- Now "mviews" has one record from cs_materialized_views

             PERFORM cs_log(''Refreshing materialized view '' || quote_ident(mviews.mv_name) || ''...'');
             EXECUTE ''TRUNCATE TABLE  '' || quote_ident(mviews.mv_name);
             EXECUTE ''INSERT INTO '' || quote_ident(mviews.mv_name) || '' '' || mviews.mv_query;
         END LOOP;

         PERFORM cs_log(''Done refreshing materialized views.'');
         RETURN 1;
    end;
    ' LANGUAGE 'plpgsql';

If the loop is terminated by an EXIT statement, the last assigned row value is still accessible after the loop.

The FOR-IN-EXECUTE statement is another way to iterate over records:

    [<<label>>]
    FOR record | row IN EXECUTE text_expression LOOP
        statements
    END LOOP;

This is like the previous form, except that the source SELECT statement is specified as a string expression, which is evaluated and re-planned on each entry to the FOR loop. This allows the programmer to choose the speed of a pre-planned query or the flexibility of a dynamic query, just as with a plain EXECUTE statement.

> Note: The PL/pgSQL parser presently distinguishes the two kinds of FOR loops (integer or record-returning) by checking whether the target variable mentioned just after FOR has been declared as a record/row variable. If not, it's presumed to be an integer FOR loop. This can cause rather nonintuitive error messages when the true problem is, say, that one has misspelled the FOR variable name.

Prev | Home | Next
Basic Statements | Up | Cursors