path: root/newtitle.s

; this file needs to be assembled with:
; cl65 -o newtitle.xex -t none newtitle.s
; It contains only an init routine, no run address.

 .include "atari.inc"

 ; location sound code will look at to see whether sound
 ; is disabled (0 = enabled, !0 = disabled). If you
 ; change this here, change it in sounds.h also!
sound_disabled = $06ff

 ; since we're changing the font and colors, we'll save the old
 ; ones here. If you change these, change them in taipan.c
 ; also.
fontsave = $06fc
color1save = $06fd
color2save = $06fe

 ; where our screen was loaded (see newtitle.pl)
;screendata = $2400

 ; homebrew atari xex header
 .word $ffff
 .word origin
 .word end-1

; .org $a800
 .org origin

version:
 .incbin "ver.dat"

help:
 .incbin "help.dat"

helphitbl:
 .byte >version
 .byte >help
 .byte >(help+32)
 .byte >(help+64)
 .byte >(help+96)
 .byte 0

helplotbl:
 .byte <version
 .byte <help
 .byte <(help+32)
 .byte <(help+64)
 .byte <(help+96)
 .byte 0

colorchoices:
 .byte $c0,$10,$00
colorcount = (*-colorchoices)-1
textchoices:
 .byte $0c,$0e,$0a
textcount = (*-textchoices)-1

wait1jiffy:
 lda RTCLOK+2
wait:
 cmp RTCLOK+2
 beq wait
 rts

; this is needed to prevent the DL from crossing a 1K boundary.
filler:
 .repeat 3
  .byte $aa
 .endrepeat

; since the screen data crosses a 4K boundary, we have to
; include a LMS. screendata needs to be on a 32-byte boundary for
; these calculations to work.
 .if(screendata .mod $20)
  .error "screendata must be on a 32-byte boundary!"
 .endif

totalscanlines = 184 ; aka image size / $20
topscanlines = (($1000 - (screendata .mod $1000)) / $20)
bottomscanlines = totalscanlines - topscanlines

 .out .sprintf("topscanlines = %d", topscanlines)
 .out .sprintf("bottomscanlines = %d", bottomscanlines)

; if the display list crosses a 1K boundary, it needs to contain a
; jmp instruction ($01).
 .macro dlbyte arg
  .if((* .mod $400) = $3fd)
   .out .sprintf("emitting DL jump to $%x at $%x", * + 3, *)
   .byte $01
   .word (* + 2)
  .endif
  .byte arg
 .endmacro

 .macro dl3byte ins, arg
  .local bytes
  bytes = $400 - (* .mod $400)
  .if(bytes < 3)
   .error .sprintf("$%x %d: display list dl3byte when <3 bytes left in 1K block, sorry", *, bytes)
  .endif
  .byte ins
  .word arg
 .endmacro

 ; display list here
dlist:
 dlbyte $70 ; 24 scanlines of blanks
 dlbyte $70
 dlbyte $70

 dl3byte $0f | $40, screendata ; LMS, BASIC mode 8
 .repeat topscanlines - 1
  dlbyte $0f ; 127 more scanlines of mode 8
 .endrepeat

 dl3byte $0f | $40, screendata+(topscanlines * $20) ; Hit 4K boundary, LMS again
 .repeat bottomscanlines
  dlbyte $0f ; 55 more scanlines of mode 8
 .endrepeat
 dl3byte $02 | $40, version ; LMS, 1 line of GR.0 for the version
help_lms = * - 2
 dl3byte $41, dlist ; JVB, jump & wait for vblank

 .out .sprintf("dl start $%x, end $%x, size %d", dlist, *, (* - dlist) + 1)

 .out .sprintf("C code can load at $%x", * + 1)

helpshowing = FR1

; here is where we store N<space> or FF (inverse)
sounddisp = help + 78

 ; executable code here
start:
 ; save old color registers and font addr.
 lda CHBAS
 sta fontsave
 lda COLOR1
 sta color1save
 lda COLOR2
 sta color2save

 ; setup color registers
 lda colorchoices
 sta COLOR2 ; text bg
 lda textchoices
 sta COLOR1 ; text fg

 ; turn off screen, in case vblank happens while we work
 lda #0
 sta FR0
 sta SDMCTL

 ; build our display list
 ; TODO, for now it's hardcoded (see 'dlist' below)

 ; wait for the next frame, to avoid graphics glitching
 jsr wait1jiffy

 ; setup our display list
 lda SDLSTL
 sta FR0
 lda SDLSTH
 sta FR0+1
 lda #<dlist
 sta SDLSTL
 lda #>dlist
 sta SDLSTH

 ; switch to narrow playfield, enable screen
 lda #$21
 sta SDMCTL

 ; clear any keypress that happened during loading
 lda #$ff
 sta CH

 ldx #0 ; X = index into bg color choices
 ldy #0 ; Y = index into text color choices

 ; wait for user to press a key
wait4key:
 lda colorchoices,x
 sta COLOR2
 lda textchoices,y
 sta COLOR1
 lda CH
 cmp #$ff
 beq wait4key
 cmp #28 ; Escape key
 bne not_esc

 ; show next line of help
showhelp:
 stx FR1+1
 ldx helpshowing
 inx
loadhelp:
 lda helphitbl,x
 bne helpok
 ldx #0
 beq loadhelp
helpok:
 sta help_lms+1
 lda helplotbl,x
 sta help_lms
 stx helpshowing
 ldx FR1+1
 clc
 bcc x_ok

not_esc:
 cmp #62 ; S key
 bne not_s
 jsr enable_disable_sound
 clc
 bcc showhelp

not_s:
 cmp #21 ; B key
 bne not_b
 dex
 bpl x_ok
 ldx #colorcount
 bne x_ok

not_b:
 cmp #45 ; T key
 bne keyok
 dey
 bpl x_ok
 ldy #textcount

x_ok:
 lda #$ff
 sta CH
 bne wait4key

keyok:
 lda CH
 cmp #33 ; space bar
 beq @done
 cmp #12 ; Enter
 bne x_ok

@done:
 ; eat the keypress
 lda #$ff
 sta CH
 rts ; return to DOS (which loads the rest of the game)

enable_disable_sound:
 lda #2
 sta helpshowing
 lda sound_disabled
 eor #$01
 sta sound_disabled
 beq now_on
 lda #166 ; inverse F screen code
 sta sounddisp
 sta sounddisp+1
 rts
now_on:
 lda #174 ; inverse N screen code
 sta sounddisp
 lda #128 ; inverse space screen code
 sta sounddisp+1
 rts

 .out .sprintf("code ends at $%x", *)

end:
 .word INITAD
 .word INITAD+1
 .word start